在gradle中，如果您没有为所使用的依赖项指定版本号，那么它们需要由其他东西提供。在你的情况下，另一个是 io.spring.dependency-management 插件。然而，它只知道 Spring 开机，如果你也有 org.springframework.boot 已应用插件。所以一旦你删除了它，依赖管理插件就不能再为依赖提供版本了。
有很多方法可以解决这个问题。以下是我能想到的主要的。都是groovy dsl。我把每一个都列为一般情况，所以你必须根据你的项目调整一下。更具体地说，您应该从根目录中删除所有插件（或者将它们设置为 apply false )并将它们添加到相关的子项目中。你也可能不需要 war 以及 idea 插件。
（顺便说一句，我个人更喜欢选择b。）

答。单独使用spring依赖管理插件

在列表中有spring引导插件，但不要应用它。这使得插件类在项目类路径上可用，因此您可以引用它。然后您可以将spring引导bom提供给依赖关系管理插件：

plugins {
    id 'org.springframework.boot' version '2.4.0' apply false // <- Apply false
    id 'io.spring.dependency-management' version '1.0.10.RELEASE'
    id 'java'
}

dependencyManagement {
    imports {
        mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
    }
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter'
}

更多信息请看这里。

b。不要使用spring依赖管理插件

这个插件的优点之一是，如果您是从maven迁移的，因为它反映了依赖关系管理规则。还有一些其他特性。但是，如果您没有使用这些特性，也没有从maven迁移，则不需要它。只需使用普通渐变语义：

plugins {
    id 'org.springframework.boot' version '2.4.0' apply false // <- Apply false
    id 'java'
}

dependencies {
    implementation platform(org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES)
    implementation 'org.springframework.boot:spring-boot-starter'
}

// OR:

plugins {
    id 'java'
}

dependencies {
    implementation platform("org.springframework.boot:spring-boot-dependencies:2.4.0")
    implementation 'org.springframework.boot:spring-boot-starter'
}

c。使用这两个插件，但禁用启动jar任务。

spring引导插件禁用了正常的 jar 任务，但您可以重新启用它。因为两者的jar文件名是相同的 jar 以及 bootJar ，你不能同时拥有它们。所以要么也禁用 bootJar 或者给它一个分类器。在这里我禁用了它。

plugins {
    id 'org.springframework.boot' version '2.4.0' // <- Apply true
    id 'io.spring.dependency-management' version '1.0.10.RELEASE'
    id 'java'
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter'
}

jar {
    enabled = true
}

bootJar {
    enabled = false
}

更多信息请看这里。
我为冗长的回答道歉。我被迷住了：）