import groovy.json.*

def body ='''
[{
    "name": "1",
    "value": "true",
    "childNodes": [{
        "name": "2",
        "value": "true",
        "childNodes": [{
            "name": "3",
            "value": "false",
            "childNodes": [{
                "name": "4",
                "value": "false"
            }]
        }]
    }]
}]
'''

def filter(arr){
    for(i in arr){
        if(i.value == 'false') return [i]
        def filteredChild = filter(i.childNodes)
        if(filteredChild)return filteredChild
    }
    return null // not found
}

def filtered = filter( new JsonSlurper().parseText(body) )
println new JsonBuilder(filtered).toPrettyString()

假设您每次只有一个子对象，并且您的任务是查找第一个value=false节点并将其与所有子节点一起返回，则可以执行以下操作：

def processData(String message) {
    def data = new JsonSlurper().parseText(message)[0]
    while (data.value != 'false') { data = data.childNodes[0] }
    return new JsonBuilder([data]).toPrettyString()
}

下面是一个Spock测试（用常规的json字符串替换了pretty字符串，这样就更容易用==来比较字符串）

class ParseSpec extends Specification {
    def testString = '''
    [{
        "name": "1",
        "value": "true",
        "childNodes": [{
            "name": "2",
            "value": "true",
            "childNodes": [{
                "name": "3",
                "value": "false",
                "childNodes": [{
                    "name": "4",
                    "value": "false"
                }]
            }]
        }]
    }]
    '''

    def processData(String message) {
        def data = new JsonSlurper().parseText(message)[0]
        while (data.value != 'false') { data = data.childNodes[0] }
        return JsonOutput.toJson([data])
    }

    def 'run test'() {
        expect:
        '''[{"name":"3","value":"false","childNodes":[{"name":"4","value":"false"}]}]''' == processData(testString)
    }
}