您可以使用get_target_property()从每个目标提取包含目录。目标的INCLUDE_DIRECTORIES属性包含该目标的包含目录。由于您有两个目标，LibraryA和LibraryB，因此我们必须调用它两次。然后，我们可以使用foreach()将包含目录列表连接在一起。如果您在编译器命令中使用这些包含目录（例如MSVC），您也可以将/Icompiler option附加到循环中的每个目录：

# Get the include directories for the target.

get_target_property(LIBA_INCLUDES LibraryA INCLUDE_DIRECTORIES)
get_target_property(LIBB_INCLUDES LibraryB INCLUDE_DIRECTORIES)

# Construct the compiler string for the include directories.

foreach(dir ${LIBA_INCLUDES} ${LIBB_INCLUDES})
    string(APPEND INCLUDE_COMPILER_STRING "/I${dir} ")
endforeach()

然后，您可以使用建构的INCLUDE_COMPILER_STRING变数呼叫自订目的命令：

add_custom_target(Bar ALL
    COMMAND ${CMAKE_C_COMPILER} thing.cpp ${INCLUDE_COMPILER_STRING} /P
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/Path/Here
    COMMENT "Preprocessing to a file"
    VERBATIM
)

如果你想要更简洁的东西，你可以使用这里的生成器表达式示例，它获取目标的包含目录，并在你的自定义目标命令中内联展开它们。

add_custom_target(Bar ALL
    COMMAND ${CMAKE_C_COMPILER} thing.cpp 
        "/I$<JOIN:$<TARGET_PROPERTY:LibraryA,INCLUDE_DIRECTORIES>,;/I>"
        "/I$<JOIN:$<TARGET_PROPERTY:LibraryB,INCLUDE_DIRECTORIES>,;/I>"
        /P
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/Path/Here
    COMMENT "Preprocessing to a file"
    VERBATIM
    COMMAND_EXPAND_LISTS
)

作为评论，目前接受的答案没有处理传递依赖。这个问题已经困惑了我一整天，所以我现在整理出来。
我在构建LibraryLinkUtilities here .这是我在项目中使用的CMakeLists.txt文件：

cmake_minimum_required(VERSION 3.15.0)

project ("CMakeProject1")

set(LLU_ROOT "D:/test/LibraryLinkUtilities/install")
set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "" FORCE)

find_package(LLU NO_MODULE PATH_SUFFIXES LLU)

add_library(${PROJECT_NAME} SHARED ${PROJECT_NAME}.cpp)

target_link_libraries(${PROJECT_NAME} PRIVATE LLU::LLU)

当我用 Visual Studio 打开**.sln时，它运行得很好，我的意思是我可以用任何构建类型构建它。但是我发现 Configuation 中的 include directories 是空的。这让我抓狂，因为我想知道项目包含了哪个目录。然后我使用函数print_target_properties fixed here打印了关于导入目标**的所有属性：

function(print_target_properties target)
    if(NOT TARGET ${target})
      message(STATUS "There is no target named '${target}'")
      return()
    endif()

    foreach(property ${CMAKE_PROPERTY_LIST})
        string(REPLACE "<CONFIG>" "DEBUG" property ${property})

        get_property(was_set TARGET ${target} PROPERTY ${property} SET)
        if(was_set)
            get_target_property(value ${target} ${property})
            message("${target} ${property} = ${value}")
        endif()
    endforeach()
endfunction()

print_target_properties(LLU::LLU)

注意红线处，LLU::LLU依赖于WSTP::WSTP和WolframLibrary::WolframLibrary .所以我用这段代码打印所有包含的目录：

include(CMakePrintHelpers)
get_target_property(LLUDEPENDS LLU::LLU INTERFACE_LINK_LIBRARIES)
cmake_print_properties(TARGETS LLU::LLU ${LLUDEPENDS} PROPERTIES INTERFACE_INCLUDE_DIRECTORIES)