对于o和O，下面是我多年前编写的几个函数：

(defun vi-open-line-above ()
  "Insert a newline above the current line and put point at beginning."
  (interactive)
  (unless (bolp)
    (beginning-of-line))
  (newline)
  (forward-line -1)
  (indent-according-to-mode))

(defun vi-open-line-below ()
  "Insert a newline below the current line and put point at beginning."
  (interactive)
  (unless (eolp)
    (end-of-line))
  (newline-and-indent))

(defun vi-open-line (&optional abovep)
  "Insert a newline below the current line and put point at beginning.
With a prefix argument, insert a newline above the current line."
  (interactive "P")
  (if abovep
      (vi-open-line-above)
    (vi-open-line-below)))

您可以将vi-open-line绑定到 M-insert，如下所示：

(define-key global-map [(meta insert)] 'vi-open-line)

对于dd，如果您希望删除的行进入删除环，可以使用以下函数 Package kill-line：

(defun kill-current-line (&optional n)
  (interactive "p")
  (save-excursion
    (beginning-of-line)
    (let ((kill-whole-line t))
      (kill-line n))))

为了完整起见，它接受一个前缀参数，并将其应用于kill-line，这样它可以删除比“当前”行更多的内容。
您还可以查看viper-mode的源代码，以了解它如何实现等效的dd、o和O命令。

C+e C+j

根据the emacs manual docs。这会得到一个新行和缩进。

对于dd，请使用“kill-whole-line”，在Emacs的最新版本中，默认情况下它绑定到“C-S-backspace”。
我应该补充一点，我自己更经常使用whole-line-or-region.el，因为C-w比C-S-backspace更容易键入。

你可以创建一个macro和bind it to a key sequence。还不需要学习任何emacslisp。

下面是我如何解决Emacs缺少类似vi的“O”命令的问题：

(defadvice open-line (around vi-style-open-line activate)
  "Make open-line behave more like vi."
  (beginning-of-line)
  ad-do-it
  (indent-according-to-mode))

有了这个，我就再也不需要vi的“o”命令的相应版本了。
至于“dd”命令，一开始有点刺耳，但我最终还是采用了Emacs的方法。（C-a C-SPC，转到我想删除的文本的另一端，C-w）。或者，如果我能看到我想删除的行数，我将用M-9 C-k一次删除九行。

我知道，这个回答并不是直接的，但是像一个Vim用户一样，我发现Spacemacs是从Vim迁移到emacs的功能最强的emacs入门包。你可以将它配置为类似Vim、类似emacs或混合。
http://spacemacs.org/
给予看。

只要使用Viper-mode，Vimpulse或Vim Mode，Emacs的键绑定就不符合人体工程学。

经过几次搜索和实验，我根据其他答案得出了以下结论：

• Vim上的dd命令：Emacs上的C-S-backspace
• Vim上的o命令：Emacs上的C-e C-j
• Vim上的O命令：Emacs上的C-a C-j C-p

是的，emacs有时候有一些“富有表现力的”命令组合来做一些事情，但是它们有时候确实很有意义！
如果你想一想，emacs有时也会简化一些事情，而vim没有。当你想选择一个文件中的整个文本时，你在Vim上做ggVG，而在Emacs上只是C-x h！