没有任何内置的东西，所有的一切都是你引用的Monad示例的简单结果（而且，由于这个例子使用do表示法，它是如何简化为>>=运算符的用法的）：

allEvenOdds n = do
  evenValue <- [2,4 .. n]               
  oddValue <- [1,3 .. n]                
  return (evenValue,oddValue)

-- desugaring the do notation
allEvenOdds n =
  [2,4 .. n] >>= \evenValue ->
  [1,3 .. n] >>= \oddValue ->
  return (evenValue, oddValue)

-- using the list instance of Monad to replace >>= and return
allEvenOdds n =
  concatMap (\evenValue ->
    concatMap (\oddValue -> [(evenvalue, oddValue)]) [1,3 .. n]
  ) [2,4 .. n]

您可以很容易地看到“迭代”两个列表，并得到一个包含所有（偶数，奇数）对的列表，其中的值取自两个列表。
在高层次上，我们可以说单子导致迭代，仅仅是因为concatMap像map一样，对列表中的每个元素执行给定的函数，所以它隐式地迭代列表。

Monad类型类模型的列表示例 * 非确定性 *：可以将每个var <- someList看作是一个for循环，就像Python中一样。
do表示法被去糖化为[2,4 .. n] >>= (\evenValue -> [1, 3 .. n] >>= (\oddValue -> return (evenValue, oddValue)))，所以这相当于Python中的一些内容：

result = []
    for evenValue in range(2, n, 2):
        for oddValue in range(1, n, 2):
            result.append((evenValue, oddValue))

或者使用列表解析：

result = [
        (evenValue, oddValue)
        for evenValue in range(2, n, 2)
        for oddValue in range(1, n, 2)
    ]

这是因为对于instance Monad []，表达式[2,4 .. n] >>= (\evenValue -> [1, 3 .. n] >>= (\oddValue -> return (evenValue, oddValue)))因此等效于：

concatMap (\evenValue -> [1, 3 .. n] >>= (\oddValue -> return (evenValue, oddValue))) [2,4 .. n]

从而：

concatMap (\evenValue -> concatMap (\oddValue -> [(evenValue, oddValue)]) [1, 3 .. n]) [2,4 .. n]

但是，do符号并没有“硬连接”到IO：IO只是Monad的一个示例，它的实现方式是一个IO操作在第二个之前运行。对于列表，它的实现方式等同于跨越Python for循环。