在关于xml-hamlet的Yesod Book文档的开头，他们展示了如何使用xml-conduit API从xml-conduit生成XML。

{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE OverloadedLists #-}

import qualified Data.Text.Lazy.IO as Text
import qualified Data.Map as Map
import Text.XML

myFoo = Element "foo" [("attribute", "something")]
  [ NodeElement $ Element "bar" []
    [ NodeElement $ Element "foobar" []
      [ NodeElement $ Element "barfoo" []
        [ NodeContent "something here" ]]]]

main = Text.putStrLn $ renderText def $ Document (Prologue [] Nothing []) myFoo []

给出：

> main
<?xml version="1.0" encoding="UTF-8"?><foo attribute="something">
<bar><foobar><barfoo>something here</barfoo></foobar></bar></foo>

主要的问题是语法，但是使用简单的Haskell函数编写自己的类似于清晰的DSL并不困难。如果你想要一个完全灵活的语法，并且不依赖于模式，你可以编写：

-- helpers
attr_ = (,)
element_ nam attrs bdy = NodeElement $ Element nam (Map.fromList attrs) bdy
text_ = NodeContent

-- elements
foo_ = element_ "foo"
bar_ = element_ "bar"
foobar_ = element_ "foobar"
barfoo_ = element_ "barfoo_"

-- attributes
attribute_ = attr_ "attribute"

-- used to unwrap a top level Node to an Element
unNode (NodeElement x) = x

myFoo = unNode $
  foo_ [attribute_ "something"] $
    [ bar_ []
      [ foobar_ []
        [ barfoo_ []
          [ text_ "something here" ]]]]

main = Text.putStrLn $ renderText def $ Document (Prologue [] Nothing []) myFoo []

通常，语法可以通过考虑你的（非正式的）模式来简化。如果barfoo没有属性，只能包含一个文本块，那么你可以写：

barfoo_ txt = element_ "barfoo" [] [text_ txt]

并将其用作barfoo_ "something here"。

我经常找不到足够的例子来轻松地开始使用新的Haskell库。
因此，虽然问答Which Haskell XML library to use?是从2009年和生态系统已经移动，答案可能是不一样的第一次检查，这个问答是第一次击中我时，谷歌“Haskell XML网站：stackoverflow.com“，所以它可能是值得修改的答案。（另外，还有一个选项可以关闭要求软件推荐的问题，这可能是因为答案既主观又随时间变化。）
如果我用search Hackage for "xml"并交叉引用这两个列表，看起来候选者大多数是相同的，而且似乎只有一个大的竞争者进入了，那就是xml-conduit。但是，与其根据它们的“DL”和更新的时间等来评估软件包（它们看起来有点相等），你可以依赖给出的答案：

1. xml（如果任务很简单）
   在GitHub README中只有一个例子：

{-# LANGUAGE RecordWildCards #-}
import Text.XML.Light

data Package = Package
  { pOrderNo  :: String
  , pOrderPos :: String
  , pBarcode  :: String
  , pNumber   :: String
  }

-- | Create XML from a Package
instance Node Package where
  node qn Package {..} =
    node qn
      [ unode "package_number" pNumber
      , unode "package_barcode" pBarcode
      , unode "order_number" pOrderNo
      , unode "order_position" pOrderPos
      ]

我去找了一个使用xml库的库来做一个更好的例子。做一个reverse dependency search for "xml"，你会得到一些类似大卫Himmelstrup的reanimate-svg的东西，它给我的印象可能是最近的，可能是一个很好的、简单的用法。这里，Graphics.SvgTree介绍了从字符串解析XML和将XML保存到文件中。Graphics.SvgTree.XmlParser涵盖了XML和某些数据类型之间的相互转换（在本例中，Document是SVG）。