安迪的答案是一个很好的答案，除了他uc s每一个关键，然后uc s它再次如果它不匹配。
这uc s它一次：

%hash = map { uc $_ => $hash{$_} } keys %hash;

但是，既然你谈到了用户 * 存储密钥 *，平局是一个更确定的方式，即使较慢。

package UCaseHash;
require Tie::Hash;

our @ISA = qw<Tie::StdHash>;

sub FETCH { 
    my ( $self, $key ) = @_;
    return $self->{ uc $key };
}

sub STORE { 
    my ( $self, $key, $value ) = @_;
    $self->{ uc $key } = $value;
}

1;

然后在主要：

tie my %hash, 'UCaseHash';

tie的“魔力”将其封装起来，这样用户就不会在不知情的情况下弄乱它。
当然，只要使用“类”，就可以传入配置文件名并从那里初始化它：

package UCaseHash;
use Tie::Hash;
use Carp qw<croak>;

...

sub TIEHASH { 
    my ( $class_name, $config_file_path ) = @_;
    my $self = $class_name->SUPER::TIEHASH;
    open my $fh, '<', $config_file_path 
        or croak "Could not open config file $config_file_path!"
        ;
    my %phash = _process_config_lines( <$fh> );
    close $fh;
    $self->STORE( $_, $phash{$_} ) foreach keys %phash;
    return $self;
}

在那里你会不得不这样称呼它：

tie my %hash, 'UCaseHash', CONFIG_FILE_PATH;

......假设某个常数CONFIG_FILE_PATH。

遍历散列，将所有小写键替换为大写键，并删除旧键。大致如下：

for my $key ( grep { uc($_) ne $_ } keys %hash ) {
    my $newkey = uc $key;
    $hash{$newkey} = delete $hash{$key};
}

这会将多级哈希转换为小写

my $lowercaseghash = convertmaptolowercase(\%hash);

sub convertmaptolowercase(){
    my $output=$_[0];
    while(my($key,$value) = each(%$output)){
        my $ref;
        if(ref($value) eq "HASH"){
            $ref=convertmaptolowercase($value);
        } else {
           $ref=$value;
        }
        delete $output->{$key}; #Removing the existing key
        $key = lc $key;
        $output->{$key}=$ref; #Adding new key
    }
    return $output;
}

我来这里是为了寻找一个答案，并想分享我的一些经验。为了确保GET/POST参数、模板和存储过程之间的兼容性，我想确保通过$cgi-〉Vars获得的所有键都是大写的，并且没有剩余的小写“重复”键。下面是基本的脚本...

use CGI;
use Data::Dumper;

my $cgi = CGI->new;

print "Content-Type: text/html\n\n";

$params = $cgi->Vars();

print "<p>Before - ", Dumper($params);

map { 
    if ( $_ =~ qr/[a-z]+/mp ){ 
        $params->{uc $_} = $params->{$_}; 
        delete($params->{$_}); 
    }  
} keys %{$params};

print "<p>After - ", Dumper($params);

exit;

输出如下所示...

Before - $VAR1 = { 'table' => 'orders', 'SALESMAN_ID' => '2', 'customer_id' => '49' };

After - $VAR1 = { 'SALESMAN_ID' => '2', 'TABLE' => 'orders', 'CUSTOMER_ID' => '49' };