perl 如何按数字对字符串列表进行排序？

yx2lnoni 于 2022-11-15 发布在 Perl

关注(0)|答案(4)|浏览(301)

我有一个文件名列表，如下所示：

fw_d.log.1.gz  
through  
fw_d.log.300.gz

当我使用下面的代码块时，它几乎按照我想要的方式排序，但并不完全是这样：

#!/usr/bin/perl -w
my $basedir = "/var/log";
my @verdir = qw(fw_d);
my $fulldir;
my $configs;
my $combidir;

foreach $combidir (@verdir) {
    $fulldir = "$basedir/$combidir";
    opendir (DIR, $fulldir);
    my @files = grep { $_ ne '.' && $_ ne '..' && $_ ne 'CVS' readdir DIR;
    closedir (DIR);
    @files1 = sort {$a cmp $b}(@files);
    foreach my $configs (@files1) {
        print "Checking $configs\n";
        system("less $basedir/$combidir/$configs | grep \'.* Group = , Username = .* autheauthenticated.\' >> output.log" );
    }
}

下面是一个代码段输出：

Checking fw_d.log  
Checking fw_d.log.1.gz  
Checking fw_d.log.10.gz  
Checking fw_d.log.100.gz  
Checking fw_d.log.101.gz  
Checking fw_d.log.102.gz

正如你所看到的，它几乎排序它如何我希望...有人有任何建议，无论是阅读，或代码片段，我可以使用？

perl

来源：https://stackoverflow.com/questions/6282574/how-can-i-sort-a-list-of-strings-by-numbers-in-them

4条答案

按热度按时间

kmpatx3s1#

您可以使用Schartzian-transform：

my @sorted = map  { $_->[0] }
             sort { $a->[1] <=> $b->[1] }
             map  { [$_, $_=~/(\d+)/] }
                 @files;
print Dumper \@sorted;

添加了Schwartzian变换和子例程之间的比较基准

use Benchmark qw(:all);

# build list of files
my @files = map {'fw_d.log.'.int(rand()*1000).'.log' } 0 ..300;

my $count = -3;
my $r = cmpthese($count, {
        'subname' => sub {
              sub expand {
                   my $file=shift; 
                   $file=~s{(\d+)}{sprintf "%04d", $1}eg;
                   return $file;
              }
              my @sorted = sort { expand($a) cmp expand($b) } @files;
        },
        'schwartzian' => sub {
              my @sorted = map  { $_->[0] }
                           sort { $a->[1] <=> $b->[1] }
                           map  { [$_, $_=~/(\d+)/] }
                 @files;
         }
});

结果：

Rate     subname schwartzian
subname     21.2/s          --        -92%
schwartzian  279/s       1215%          --

对于300个文件的排序，Schwartzian变换的效率提高了大约13倍。

赞(0）回复(0）举报 2022-11-15

vq8itlhq2#

问题是代码会按照你的要求去做：按字母顺序对文件名进行排序。
应将sort { $a cmp $b }替换为sort { expand($a) cmp expand($b) }
使用expand：

sub expand 
   { my $file=shift; 
     $file=~s{(\d+)}{sprintf "%04d", $1}eg; # expand all numbers to 4 digits
     return $file;
   }

赞(0）回复(0）举报 2022-11-15

ltskdhd13#

您可以尝试使用自定义排序函数：

sub sort_by_number {
    $a =~ /(\d+)/;
    $numa = $1;
    $b =~ /(\d+)/;
    $numb = $1;

    return $numa <=> $numb;
}

然后这样排序：

@files1 = sort sort_by_number @files;

这将按每个字符串中第一个数字的值对@files中的字符串进行排序。

赞(0）回复(0）举报 2022-11-15

lymnna714#

老问题，但有一个答案尚未提及。
Sort::Naturally会为您执行以下操作：
按词法排序，但按数字排序数字部分

#!/usr/bin/env perl
use strict;
use warnings;

use Sort::Naturally;

print nsort <DATA>;

__DATA__
fw_d.log  
fw_d.log.101.gz  
fw_d.log.1.gz  
fw_d.log.10.gz  
fw_d.log.100.gz 
fw_d.log.2.gz  
fw_d.log.102.gz  
fw_d.log.12.gz

此命令为：

fw_d.log  
fw_d.log.1.gz  
fw_d.log.2.gz  
fw_d.log.10.gz  
fw_d.log.12.gz
fw_d.log.100.gz 
fw_d.log.101.gz  
fw_d.log.102.gz

赞(0）回复(0）举报 2022-11-15

我来回答

perl 如何按数字对字符串列表进行排序？

4条答案

相关问题

热门标签

最新问答