一种方法是将所有输入分解为单词，然后每三个单词打印一行

use warnings;
use strict; 
use feature 'say';

die "Usage: $0 filename\n" if not @ARGV;

# "Slurp" into a variable the file with the name given on the command line
my $content = do { local $/; <> };

my @words = split ' ', $content;

say join(' ', splice @words, 0, 3)  while @words;

当以scriptname.pl input-filename运行时，这将根据需要打印给定的输入文件。
下面是一个必要的解释。
在Perl程序中，命令行中给出的参数是@ARGV，所以我们首先测试@ARGV是否可能为空;如果用户确实没有提供所需的参数（在这里输入文件名），程序就无能为力，我们die（在这种情况下退出），并给出一条简洁的用法信息。†
文件被读入do块中的字符串中。“input record separator”（$/变量）‡被本地化到块中，当它未被定义时，<>操作符读取整个文件，文件名为@ARGV，因此命令行中给出了（第一个）文件名。这被赋值给$content，我们得到了文件。
然后，split使用惯用的' '模式将该字符串用任何空格分隔，从而给出文件中的单词列表。
最后，splice删除并返回前三个单词，这三个单词用空格连接在一起并打印在一行上，只要@words中还有任何元素，它就一直这样做（如果目标数组中没有三个元素，它就会删除所有元素，最终耗尽并清空数组）。
所有这些都可以用一句话来概括，但在这里没有理由进行这样的杂技。
更重要的是，这可以通过使用库来完成，我们可以使用Path：：Tiny：：slurp将文件读入变量，然后使用List：：MoreUtils：：natatime（n-at-a-time）处理元素组。
† die语句末尾的\n隐藏了... at program-name line 5.，后者通常会被打印出来，因为它在这里没有什么意义。这是非常基本的，还有更好的方法来提供和处理用户输入。参见Getopt::Long
‡参见perlvar中的本节

请调查以下代码段是否符合您问题
注意：要从文件读取数据，请将<DATA>替换为<>

use strict;
use warnings;

my($num,$count) = (3,1);
my @array = split(' ', do { local $/; <DATA> });

print $_, ($count++ % $num) ? ' ': "\n" for @array;

__DATA__
TTAA 58231 63741 99823 15423 17003 70152 07604 29517 50586 04381
08513 40758 16182 11524 30967 31964 00510 25094 41365 25503
20241 53562 10512 15419 68542 07540 10656 76156 11024 88123
76950 09548 77999 31313 47708 82318=

输出量

TTAA 58231 63741
99823 15423 17003
70152 07604 29517
50586 04381 08513
40758 16182 11524
30967 31964 00510
25094 41365 25503
20241 53562 10512
15419 68542 07540
10656 76156 11024
88123 76950 09548
77999 31313 47708
82318=

你的代码和split工作正常。要理解你的问题，你应该了解你的代码实际上是做什么的。首先如果你这样做。

my @alldata=<$TMP>;

然后读取数组中的整个文件，但每一行末尾仍包含一个换行符。
然后你join每行加一个空格成一串。

my $oneline=join(" ", @alldata);

但是换行符不会被删除。例如，如果你有数组。

["foo\n", "bar\n", "baz\n"]

然后用一个空格加入这个数组，就得到了这个字符串

"foo\n bar\n baz\n"

如果你打印这个字符串，那么它肯定会打印多行，因为它仍然包含多行。你可以在加入数组之前先把它吃掉，从而避免这个问题。

chomp @data;
my $str  = join " ", @data;

在上面有一个特殊的情况，当你使用split时，它只包含一个空格。然后它被当作split /\s+/来处理。这意味着它不仅在一个空格字符上拆分，而且在所有空格字符上拆分，并且一次拆分多个空格字符。
另外，有时候最好使用正则表达式来删除换行符。

s/\r?\n// for @data;

默认情况下，chomp会删除一个特定于操作系统的换行符。因此在Linux上它只会删除\n，在Windows上它会删除\r\n。但是如果你在跨平台文件上工作，最好用正则表达式删除换行符，因为它总是处理这两种情况。
当你把每一条线连接起来之后，你可以再把它分开。
因此，您的代码可能如下所示：

# Remove newline at end of every line
s/\r?\n// for @data;

# join every line with whitespace
my $str = join " ", @data;

# split into tokens
my @tokens = split /\s+/, $str;

例如，要在一行上打印10个项目，可以使用类似下面的代码。完整示例：

my @data = <DATA>;

# Remove newline at end of every line
s/\r?\n// for @data;

# join every line with whitespace
my $str = join " ", @data;

# split into tokens
my @tokens = split /\s+/, $str;

# print 10 tokens on every line
my $counter = 0;
for my $token (@tokens) {
    print $token, " ";
    if ( ++$counter == 10 ) {
        print "\n";
        $counter = 0;
    }
}

__DATA__
TTAA 58231 63741
99823 15423 17003
70152 07604 29517
50586 04381 08513
40758 16182 11524
30967 31964 00510
25094 41365 25503
20241 53562 10512
15419 68542 07540
10656 76156 11024
88123 76950 09548
77999 31313 47708
82318=

但是在我看来，如果你想用whitesapce来分割所有的东西，而忽略那些行，你可以做得更好，把每一行都分割开，然后把结果推到一个数组上，这样做。

my @tokens;
for my $line (<DATA>) {
    push @tokens, split(/\s+/, $line);
}

我之所以要这样做的一个原因是，这样做更容易工作，而且你也不需要读整个文件，例如，如果你愿意，你也可以很容易地把数字插入到@tokens中：

my @tokens;

for my $line (<DATA>) {
    # Extracts only numbers from a line
    my @vals = $line =~ m/\d+/g;
    push @tokens, @vals;
}

您甚至可以进一步将所有内容简化为。

my @tokens = map { m/\d+/g } <DATA>;

map为每个数组元素执行代码块。在本例中，为<DATA>中的每一行执行代码块，并将当前行放入特殊变量$_中。一个单独的正则表达式默认情况下匹配$_。m/\d+/g匹配$_，并将其拆分为多个元素，每行的所有元素都放入@tokens中。