请使用所示示例尝试以下awk代码

awk '
/^##/ && match($0,/docker image[[:space:]]+[^:]*/){
  split(substr($0,RSTART,RLENGTH),arr1)
  print "for "arr1[3]
  next
}
match($0,/^\|\[[^]]*/){
  print substr($0,RSTART+2,RLENGTH-2)
}
'  Input_file

***说明：***增加上述awk代码的详细说明。

awk '                                   ##Starting awk program from here.
/^##/ && match($0,/docker image[[:space:]]+[^:]*/){  ##Checking condition if line starts from ## AND using match function to match regex docker image[[:space:]]+[^:]* to get needed value.
  split(substr($0,RSTART,RLENGTH),arr1) ##Splitting matched part in above match function into arr1 array with default delimiter of space here.
  print "for "arr1[3]                   ##Printing string for space arr1 3rd element here
  next                                  ##next will skip all further statements from here.
}
match($0,/^\|\[[^]]*/){                 ##using match function to match starting |[ till first occurrence of ] here.
  print substr($0,RSTART+2,RLENGTH-2)   ##printing matched sub string from above regex.
}
'  Input_file                           ##mentioning Input_file name here.

使用GNU awk（我假设您已经有了或者可以得到，因为您使用的是GNU grep），将第三个参数与match（）匹配：

$ cat tst.awk
match($0,/^###.* ([^:]+):.*/,a) { print "For", a[1] }
match($0,/\[([^]]+)/,a)         { print a[1] }
!NF

$ awk -f tst.awk file
For alarm-integrator
CVE-2020-29361
CVE-2021-35515

For br-agent
CVE-2020-29361
CVE-2021-23214

使用awk可以执行以下操作：

awk -v FS=' |[[]|[]]' '/^[#]+/{sub(/:.*$/,"");print "For " $NF} /^\|\[/{print  $2} /^$/ {print ""}' file
For alarm-integrator
CVE-2020-29361
CVE-2021-35515

For br-agent
CVE-2020-29361
CVE-2021-23214

• 我们将字段分隔符FS配置为|[[]|[]]：空格、[字符或]字符。
• 第一个条件-操作用于获取For alarm-integrator和For br-agent
• 第二个条件-all CVE numbers的操作
• 最后添加空行。

可读性更强：

awk -v FS=' |[[]|[]]' '
/^[#]+/{sub(/:.*$/,"");print "For " $NF}
/^\|\[/{print  $2}
/^$/ {print ""}
' file
For alarm-integrator
CVE-2020-29361
CVE-2021-35515

For br-agent
CVE-2020-29361
CVE-2021-23214