更改区域设置时，Thread.CurrentThread.CurrentCulture或（CultureInfo.CurrentCulture）不会 * 自动 * 更新。
您可以调用CultureInfo.ClearCachedData()来重置内部CultureData存储的设置并重新加载 fresh 值。
要在用户设置更改时更新UI，您可以处理系统在这些设置更改时发送的通知。
确认这些通知的一个简单方法是处理WM_SETTINGCHANGE消息，该消息在系统设置中的 * 某些内容 * 发生更改时发送到所有顶级Windows。
这些通知有些 * 通用 *（阅读文档），但是通过检查WParam和LParam值，您可以大致了解发生了什么变化。
覆写表单中的WndProc以行程WM_SETTINGCHANGE消息。
当您得到一个，验证哪些设置已更改，并根据此信息采取行动。
在这种情况下，当区域（用户）设置更改时，WParam将设置为0，并且LParam指向读取"intl"的字符串。
然后，如果语言是RTL（或非特定的阿拉伯语-使用CultureInfo.GetCultureInfo("AR")得到的语言），则设置自定义格式，否则可以设置默认的ShortTimePattern或其他格式。
（假设DateTimePicker控件命名为DateTimePicker1）

Private Const WM_SETTINGCHANGE As Integer = &H1A

Protected Overrides Sub WndProc(ByRef m As Message)
    Select Case m.Msg
        Case WM_SETTINGCHANGE
            Dim lparmSetting = Marshal.PtrToStringAuto(m.LParam)
            If m.WParam.ToInt32() = 0 AndAlso lparmSetting.Equals("intl") Then
                CultureInfo.CurrentCulture.ClearCachedData()
                DateTimePicker1.CustomFormat = If(CultureInfo.CurrentCulture.TextInfo.IsRightToLeft,
                    "tt mm:hh", CultureInfo.CurrentCulture.DateTimeFormat.ShortTimePattern)
            End If
    End Select
    MyBase.WndProc(m)
End Sub

次要：
由于您的自定义格式 * 并非完全标准 *，因此在首次加载表单时，您可能会有不同的行为，具体取决于运行应用程序的计算机的当前区域设置。
您可以发送一条WM_SETTINGCHANGE消息给 * 您自己 *，并按照说明设置WParam和LParam，这样您就可以在启动时 * 自动 * 更新和格式化DateTimePicker。
在Form.Load（或OnLoad()、OnShown()或OnHandleCreated()）中，您可以添加：

Imports System.Runtime.InteropServices

Protected Overrides Sub OnLoad(e As EventArgs)
    MyBase.OnLoad(e)
    SendMessage(Me.Handle, WM_SETTINGCHANGE, IntPtr.Zero, Marshal.StringToHGlobalAuto("intl"))
End Sub

SendMessage声明：

<DllImport("user32.dll", CharSet:=CharSet.Auto, SetLastError:=True)>
Friend Shared Function SendMessage(hWnd As IntPtr, uMsg As Integer, wParam As IntPtr, lParam As IntPtr) As Integer
End Function