注册表匹配：

除了@RonRosenfeld给出的答案之外，还可以应用'The Best Regex Trick Ever'，这意味着首先匹配捕获组中您不想要的内容，然后匹配您想要的内容。例如：

^.*\]|(\w+\.)

请参见在线demo，简而言之，这意味着：

• ^.*\]-匹配从字符串开头到最后出现的右方括号之间的0+（贪婪）个字符;
• |-或;
• (\w+\.)-捕获组包含1+（贪婪）以点结尾的单词字符。

以下是它在UDF中的工作方式：

Sub Test()

Dim s As String: s = "some text [asred.] ost. |Monday - Ribben (ult.) lot. ac, sino. other maybe long text; collan. "

Debug.Print RegExtract(s, "^.*\]|(\w+\.)")

End Sub

'------

'The above Sub would invoke the below function as an example.
'But you could also invoke this through: `=RegExtract(A1,"^.*\]|(\w+\.)")`
'on your sheet.

'------

Public Function RegExtract(Txt As String, Pattern As String) As String

Dim rMatch As Object, arrayMatches(), i As Long

With CreateObject("vbscript.regexp")
    .Global = True
    .Pattern = Pattern
    If .Test(Txt) Then
        For Each rMatch In .Execute(Txt)
            If Not IsEmpty(rMatch.SubMatches(0)) Then
                ReDim Preserve arrayMatches(i)
                arrayMatches(i) = rMatch.SubMatches(0)
                i = i + 1
            End If
        Next
        RegExtract = Join(arrayMatches, " ")
    Else
        RegExtract = "No match found"
    End If
End With

End Function

正则表达式替换：

根据你想要的输出，你也可以使用替换函数。你必须用另一个替代字符来匹配剩下的字符。例如：

^.*\]|(\w+\.\s?)|.

简单地说，这意味着我们添加了另一个选择，它是简单的任何单个字符。第二个小的补充是，我们在第二个选择中添加了一个 optional 空格字符\s?。

Sub Test()

Dim s As String: s = "some text [asred.] ost. |Monday - Ribben (ult.) lot. ac, sino. other maybe long text; collan. "

Debug.Print RegReplace(s, "^.*\]|(\w+\.\s?)|.", "$1")

End Sub

'------

'There are now 3 parameters to parse to the UDF; String, Pattern and Replacement.

'------

Public Function RegReplace(Txt As String, Pattern As String, Replacement) As String

Dim rMatch As Object, arrayMatches(), i As Long

With CreateObject("vbscript.regexp")
    .Global = True
    .Pattern = Pattern
    RegReplace = Trim(.Replace(Txt, Replacement))
End With

End Function

请注意，我使用了Trim()来删除可能的尾随空格。
RegexMatch和RegexReplace当前都返回一个字符串来清除输入，但前者确实给予了处理arrayMatches（）变量中数组的选项。

有一个方法可以返回从某个模式开始的字符串中的所有匹配项。但是我现在想不起来了。
同时，最简单的方法似乎是删除第一个]之前的所有内容，然后对剩余部分应用Regex。
例如：

Option Explicit
Sub findit()
  Const str As String = "some text [asred.] ost. |Monday - Ribben (ult.) lot. ac, sino. other maybe long text; collan."
  Dim RE As RegExp, MC As MatchCollection, M As Match
  Dim S As String
  Dim sOutput As String
  
S = Mid(str, InStr(str, "]"))

Set RE = New RegExp
With RE
    .Pattern = "\w+(?=\.)"
    .Global = True
    If .Test(S) = True Then
        Set MC = .Execute(S)
        For Each M In MC
            sOutput = sOutput & vbLf & M
        Next M
    End If
End With

MsgBox Mid(sOutput, 2)

End Sub

• 您当然可以使用计数器而不是For each循环将匹配数限制为5 *

可以 使用 以下 正则 表达式

([a-zA-Z]+)\.

中 的 每 一 个
让 我 解释 一下 。
[a-zA-Z] - 查找 包含 从 a 到 z 和 从 A 到 Z 的 任意 字母 的 所有 内容 ， 但 只 匹配 第 一 个 字母 。
\+ - 使用 此 命令 ， 您 可以 告诉 匹配 所有 字母 ， 直到 它 找到 不是 从 a 到 z 和 从 A 到 Z 的 字母 的 内容
\. - 有 了 这个 ， 你 就 可以 在 比赛 结束 时 找到 。
这里 的 example 。