groovy 控制器返回Micronaut控制器中JSON格式的LocalDateTime

wfsdck30 于 2022-11-21 发布在其他

关注(0)|答案(2)|浏览(160)

环境：

微型机： 3.7.3
Java ：开放式 JDK 11.0.16
外观： 3.0.13

My Controller 是用 Groovy 实现的，如下所示：

@Controller("/")
@Slf4j
class Controller1 {
    @Get(uri="/test-localdatetime", produces = MediaType.APPLICATION_JSON)
    HttpResponse<String> testLocalDateTime() {
        LocalDateTime now = LocalDateTime.now()
        def map = [
                status: "SSUCCESS",
                time: now
        ]
        return HttpResponse.ok(map)
    }
}

中的每一个
当我呼叫它时，它会传回：

{"status":"SSUCCESS","time":[2022,11,2,8,24,13,948454300]}

格式
如果我想让它返回一个如下所示的美化 JSON ，我可以添加以下代码

String json = new JsonBuilder(map).toPrettyString()
return HttpResponse.ok(json)

格式
而回应会变成（仍然不是我想要的）：

{
    "status": "SSUCCESS",
    "time": {
        "month": "NOVEMBER",
        "second": 29,
        "hour": 8,
        "nano": 944749300,
        "year": 2022,
        "dayOfMonth": 2,
        "minute": 44,
        "monthValue": 11,
        "dayOfWeek": "WEDNESDAY",
        "chronology": {
            "calendarType": "iso8601",
            "id": "ISO"
        },
        "dayOfYear": 306
    }
}

格式
但我想要的想法回应是以下格式：

{
  "status":"SSUCCESS",
  "time":"2022-11-02 08:24:13"
}

格式
所以，我想知道是否有一种简单的方法，通过添加一些配置或注解，而不改变初始代码，达到上述想法格式？

groovy

来源：https://stackoverflow.com/questions/74283270/controller-return-localdatetime-in-json-format-in-micronaut-controller

2条答案

按热度按时间

0g0grzrc1#

您需要在应用程序中自己配置Jackson序列化。yml

jackson:
   dateFormat: yyyyMMdd
   timeZone: UTC
   serialization:
     writeDatesAsTimestamps: false

顺便说一下，我强烈建议使用java.time.Instant而不是java.time.LocalDateTime。
此外，我会将控制器的返回类型更改为返回Map而不是String，这样框架就可以关注对Map的序列化，因为返回的是Map而不是字符串。

@Controller("/")
@Slf4j
class Controller1 {
    @Get(uri="/test-localdatetime", produces = MediaType.APPLICATION_JSON)
    HttpResponse<Map> testLocalDateTime() {
        LocalDateTime now = LocalDateTime.now()
        def map = [
                status: "SSUCCESS",
                time: now
        ]
        return HttpResponse.ok(map)
    }
}

赞(0）回复(0）举报 2022-11-21

wvt8vs2t2#

当您只在一个位置使用日期/时间，或需要在不同位置使用不同格式时，您可以：

返回DTO，您可以在其中按注解设置格式

示例DTO类

import com.fasterxml.jackson.annotation.JsonFormat
import java.time.LocalDateTime

class SomeResponse {
    String status
    @JsonFormat(shape = JsonFormat.Shape.STRING, pattern = "yyyy-MM-dd HH:mm:ss")
    LocalDateTime time
}

控制器方法：

@Get(uri="/test-localdatetime", produces = MediaType.APPLICATION_JSON)
SomeResponse testLocalDateTime() {
    new SomeResponse(
        status: "SSUCCESS",
        time: LocalDateTime.now()
    )
}

继续使用Map，但手动转换时间值

控制器变更：

final static def formatter = DateTimeFormatter.ofPattern("yyyy-MM-dd HH:mm:ss")

@Get(uri="/test-localdatetime", produces = MediaType.APPLICATION_JSON)
Map testLocalDateTime() {
    def now = LocalDateTime.now()
    [
        status: "SSUCCESS",
        time: formatter.format(now)
    ]
}

赞(0）回复(0）举报 2022-11-21

我来回答

groovy 控制器返回Micronaut控制器中JSON格式的LocalDateTime

2条答案

相关问题

热门标签

最新问答