你的JSON字符串包含一个嵌入在另一个数组中的数组。你可以获取第一个数组的值（“result”）并迭代它的元素。对于每个元素，你都有一个“animals”数组，你可以迭代它来获取“id”和“name”。
简单的代码可以做到这一点：

const
    JSONStr2 =
'{' +
   '"result": [' +
     '{' +
       '"animals": [' +
         '{"id": 1, "name": "pig"},' +
         '{"id": 2, "name": "rabit"}' +
       ']' +
     '}' +
   ']' +
 '}';

 procedure TForm1.ButtonClick(Sender: TObject);
var
    JSONValue      : TJSONValue;
    JSONResult     : TJSONArray;
    JSONResultItem : TJSONValue;
    JSONAnimals    : TJSONArray;
    JSONAnimalItem : TJSONValue;
begin
    JSONValue := TJSONObject.ParseJSONValue(JSONStr);
    if not Assigned(JSONValue) then begin
        ShowMessage('JSON syntax error');
        Exit;
    end;
    try
        JSONResult := JSONValue.GetValue<TJSONArray>('result');
        for JSONResultItem in JSONResult do begin
            JSonAnimals := JSONResultItem.GetValue<TJSONArray>('animals');
            for JSONAnimalItem in JSONAnimals do begin
                Memo1.Lines.Add(Format('%s = %s',
                                       [JSONAnimalItem.GetValue<String>('id'),
                                        JSONAnimalItem.GetValue<String>('name')]));
            end;
        end;
    finally
        JSONValue.Free;
    end;
end;