NASM保持其指令简单，并具有最少的自动化功能。
它似乎不是MASM type、sizeof和length运算符的对应指令。
幸运的是，NASM采取了一种比在汇编中引入大量类型更好的方法：它开发了一个非常丰富和富有表现力的宏系统。
请考虑以下简单的宏：

;array <label>, <item directive>, <items>
%macro array 4-*
    %1: %2 %{3}                         ;label: db/dw/dd/... <firstItem>    
    %%second: %2 %{4:-1}                ;Local label (to get item size) and rest of the items
    
    %1_size EQU $ - %1                  ;Size of the array in bytes (here - label)
    %1_type EQU %%second - %1           ;Size of an item in bytes (second - label)
    %1_lengthof EQU %1_size / %1_type   ;Number of items (size of array /  size of item)
%endmacro

你可以像array my_array, dd, 1, 2, 3一样使用它。不完全像my_array dd 1, 2, 3，但很接近。
然后，您可以：

• my_array_size。数组的大小（以字节为单位）。
• my_array_type。一个数组项的大小（以字节为单位）。
• my_array_lengthof。数组中的项目数。

您可以调整宏，使其适合您的个人风格（例如：生成my_array.size和类似的，或者生成隐式地采用项声明指令的arrdb、arrdw、arrdd变体）。
示例：

BITS 32

;array <label>, <item directive>, <items>
%macro array 4-*
    %1: %2 %{3}             ;label: db/dw/dd/... <firstItem>    
    %%second: %2 %{4:-1}            ;Local label, to get item size
    
    %1_size EQU $ - %1          ;Size of the array in bytes (here - label)
    %1_type EQU %%second - %1       ;Size of an item in bytes (second - label)
    %1_lengthof EQU %1_size / %1_type   ;Number of items (size of array /  size of item)
%endmacro

;To test, use ndisam -b32
mov eax, my_array_size
mov eax, my_array_type
mov eax, my_array_lengthof
mov eax, DWORD [my_array]

;The array (ignore on output from ndisasm)
array my_array, dd, 1, 2, 3

对生成的二进制文件使用ndisam -b32：

00000000  B80C000000        mov eax,0xc
00000005  B804000000        mov eax,0x4
0000000A  B803000000        mov eax,0x3
0000000F  A114000000        mov eax,[0x14]
00000014  <REDACTED GARBAGE>