你应该把逻辑分解成更小的实用函数来完成你所需要的每一个任务（查找单词，获取单词的长度，删除单词和任何后续的空格等），这将使代码更容易阅读和维护。
例如：

function FindNextWordStart(const S: string; var Index: Integer): Boolean;
var
  Len: Integer;
begin
  Len := Length(S);
  while (Index <= Len) and (Ord(S[Index]) <= 32) do Inc(Index);
  Result := (Index <= Len);
end;

function GetWordLength(const S: string; Index: Integer): Integer;
var
  StartIdx, Len: Integer;
begin
  Len := Length(S);
  StartIdx := Index;
  while (Index <= Len) and (Ord(S[Index]) > 32) do Inc(Index);
  Result := (Index - StartIdx);
end;

procedure DeleteWord(var S: String; Index, WordLen: Integer);
var
  StartIdx, Len: Integer;
begin
  Len := Length(S);
  StartIdx := Index;
  Inc(Index, WordLen);
  while (Index <= Len) and (Ord(S[Index]) <= 32) do Inc(Index);
  Delete(S, StartIdx, Index - StartIdx);
end;

var
  UserString: string;
  StartIdx, WordLen: Integer;
begin
  Writeln('Enter the string:');
  Readln(UserString);

  StartIdx := 1;
  while FindNextWordStart(UserString, StartIdx) do
  begin
    WordLen := GetWordLength(UserString, StartIdx);
    if WordLen > 4 then
      DeleteWord(UserString, StartIdx, WordLen)
    else
      Inc(StartIdx, WordLen);
  end;

  Writeln('Result String: ', UserString);
end.

Online Demo