在这个答案中，我展示了几种修改代码的方法，第一种是对原始代码进行最小的修改，使其正常工作;最后一个是我的写法。
第一个例子只改变了rcx的起始值和结束值，它以不寻常的自上而下的顺序将数组留在堆栈中，并从数组的末尾迭代到数组的开头。

...
    subq $128, %rsp
    movq $100, -8(%rbp) # arr[0] = 100
    movq $79, -16(%rbp) # arr[1] = 79
    movq $85, -24(%rbp) # arr[2] = 85
    movq $62, -32(%rbp) # arr[3] = 62
    movq $91, -40(%rbp) # arr[4] = 91
    movq $0, -48(%rbp) # sum = 0
    movq $-5, %rcx
loop:
    cmp $0, %rcx
    jz done
    movq (%rbp, %rcx, 8), %rax
    addq %rax, -48(%rbp)
    addq $1, %rcx
    jmp loop

下一个示例以通常的方式将数组放入内存中，索引0位于最低地址，并从索引0迭代到4。请注意load指令上的偏移量，该偏移量导致索引0访问rbp-40。

...
    subq $128, %rsp
    movq $100, -40(%rbp) # arr[0] = 100
    movq $79, -32(%rbp) # arr[1] = 79
    movq $85, -24(%rbp) # arr[2] = 85
    movq $62, -16(%rbp) # arr[3] = 62
    movq $91, -8(%rbp) # arr[4] = 91
    movq $0, -48(%rbp) # sum = 0
    movq $0, %rcx # i = 0
loop:
    cmp $5, %rcx
    jz done
    movq -40(%rbp, %rcx, 8), %rax
    addq %rax, -48(%rbp)
    addq $1, %rcx
    jmp loop

最后一个例子改变了一些其他的东西，以匹配我的写作方式：

...
    subq $128, %rsp
    movq $100, -40(%rbp) # arr[0] = 100
    movq $79, -32(%rbp)  # arr[1] = 79
    movq $85, -24(%rbp)  # arr[2] = 85
    movq $62, -16(%rbp)  # arr[3] = 62
    movq $91, -8(%rbp)   # arr[4] = 91
    xor %eax, %eax       # sum = 0
    xor %ecx, %ecx       # i = 0
loop:
    addq -40(%rbp, %rcx, 8), %rax
    add $1, %ecx
    cmp $5, %ecx
    jb loop

这个版本将总和保存在寄存器中而不是内存中。它利用了这样一个事实，即写入64位寄存器的下半部分会清除寄存器的上半部分。它使用通常的技术将0加载到寄存器中。它将循环条件放在循环的底部而不是顶部。