persistent_term和ets公开了一个类似的API，但它们是不同的，我引用manual：
持久术语是一项高级功能，不能普遍替代ETS表。
不同之处在于术语存储在哪里以及更新时会发生什么，ETS术语在读取时会被复制到进程堆中，而persistent_term术语只被引用。这导致当persistent_term中的一个项被更新时，所有拥有该术语副本（引用）的进程都需要将其复制到它们的堆中才能继续使用它。
对于庞大的术语，引用它们而不是复制它们可以节省大量时间，但是更新的代价是严厉的。
同样，persistent_term只是一个Map，而ETS可以是集合、有序集合、包或复制包，ETS还提供选择和匹配语义。
persistent_term被用作ETS所用于的非常特定的使用情形的优化替代品。
关于进程字典，它是进程内部的一个本地#{}，总是可用的。ETS和persistent_term对每个进程都可用，本地进程字典对每个进程都不同。使用进程字典时要非常小心，因为它会损害可读性。

@José回答的一些免费信息：
process_dictionary是本地的，它与进程一起终止，无法从外部进程访问
persistent_element是全局的，它只会随节点而死。它可以被任何进程访问，而不受控制。
ETS由一个进程拥有，它可以被不同的进程共享，它与所有者一起消亡，所有权可以交给另一个进程，它提供一些访问控制（公共、私有、受保护）以及不同的组织类型和访问。
shell中的一个简短会话显示了（大部分）这些差异。

12> persistent_term:put(global,value1).
ok
13> put(local,value2). % with process_dictionary, put returns the previous value associated to the key
undefined
14> ets:new(my_ets,[named_table,public]). % create a public table
my_ets
15> ets:insert(my_ets,{shared,value3,other_values}).
true
16> persistent_term:get(global).  % check that everything is stored                  
value1
17> get(local).                 
value2
18> ets:lookup(my_ets,shared).
[{shared,value3,other_values}]
19> ets:lookup_element(my_ets,shared,2). % a small example of ETS extended capabilities
value3
20> F1 = fun(From) -> From ! persistent_term:get(global) end. % prepare the same functions to be executed from external process
#Fun<erl_eval.44.97283095>
21> 
21> F2 = fun(From) -> From ! get(local) end.                  
#Fun<erl_eval.44.97283095>
22> F3 = fun(From) -> From ! ets:lookup(my_ets,shared) end.
#Fun<erl_eval.44.97283095>
23> Me = self().
<0.19320.1>
24> spawn(fun() -> F1(Me) end).
<0.12906.2>
25> flush(). % persistent_term are global
Shell got value1
ok
26> spawn(fun() -> F2(Me) end).
<0.13701.2>
27> flush(). % prrocess_dictionary is local                  
Shell got undefined
ok
28> spawn(fun() -> F3(Me) end).
<0.13968.2>
29> flush().  % ETS can be shared                 
Shell got [{shared,value3,other_values}]
ok
30> 1/0. % create an exception so the shell dies and is restarted by its supervisor
** exception error: an error occurred when evaluating an arithmetic expression
     in operator  '/'/2
        called as 1 / 0
31> Me = self().  % the shell's Pid changed             
** exception error: no match of right hand side value <0.14499.2>
32> persistent_term:get(global).    % persistent are still there                          
value1
33> get(local).  % Oooops! the process dictionary is still there too. Warning, this is a side effect of the shell implementation                                             
value2
34> ets:lookup(my_ets,shared).  % my_ets does not exist anymore                      
** exception error: bad argument
     in function  ets:lookup/2
        called as ets:lookup(my_ets,shared)
35>