delphi 检测RichEdit中URL的点击

bq8i3lrv 于 2022-12-23 发布在其他

关注(0)|答案(3)|浏览(161)

我正在尝试更新RichEdit，使其能够检测URL并允许单击它以在浏览器中打开。检测URL很容易，我只使用http://www.scalabium.com/faq/dct0146.htm中的以下代码

mask := SendMessage(MNote.Handle, EM_GETEVENTMASK, 0, 0);
  SendMessage(MNote.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK);
  SendMessage(MNote.Handle, EM_AUTOURLDETECT, Integer(True), 0);

但是第二部分对我来说不起作用。他们给予了下面的代码来捕获EN_LINK消息并处理它：

type
  TForm1 = class(TForm)
  protected
    procedure WndProc(var Message: TMessage); override;
  end;
...

procedure TForm1.WndProc(var Message: TMessage);
var
  p: TENLink;
  strURL: string;
begin
  if (Message.Msg = WM_NOTIFY) then
  begin
    if (PNMHDR(Message.LParam).code = EN_LINK) then
    begin
      p := TENLink(Pointer(TWMNotify(Message).NMHdr)^);
      if (p.msg = WM_LBUTTONDOWN) then
      begin
        SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@(p.chrg)));
        strURL := RichEdit1.SelText;
        ShellExecute(Handle, 'open', PChar(strURL), 0, 0, SW_SHOWNORMAL);
      end
    end
  end;

  inherited;
end;

当我运行程序时，URL被检测到，但点击它没有任何作用。使用调试我发现当我点击URL时，Message.Msg = WM_NOTIFY不是真的。然后我尝试覆盖TRichEdit的WndProc，但结果是相同的。有什么建议吗？

delphi

来源：https://stackoverflow.com/questions/2480173/detect-click-on-url-in-richedit

3条答案

按热度按时间

lsmd5eda1#

对RichEdit的WindowProc属性进行子类化并查找CN_NOTIFY消息，例如：

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    PrevRichEditWndProc: TWndMethod;
    procedure RichEditWndProc(var Message: TMessage);
    procedure SetRichEditMasks;
  end; 

procedure TForm1.FormCreate(Sender: TObject);
begin
  PrevRichEditWndProc := RichEdit1.WindowProc;
  RichEdit1.WindowProc := RichEditWndProc;
  SetRichEditMasks;
end;

procedure TForm1.SetRichEditMasks;
var
  mask: Longint;
begin
  mask := SendMessage(RichEdit1.Handle, EM_GETEVENTMASK, 0, 0); 
  SendMessage(RichEdit1.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK); 
  SendMessage(RichEdit1.Handle, EM_AUTOURLDETECT, 1, 0);  
end;

procedure TForm1.RichEditWndProc(var Message: TMessage); 
begin 
  PrevRichEditWndProc(Message);
  case Message.Msg of
    CN_NOTIFY:
      begin
        if (TWMNotify(Message).NMHdr^.code = EN_LINK) then
        begin
          with PENLink(Message.LParam)^ do
          begin
            if (msg = WM_LBUTTONDOWN) then
            begin 
              SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@chrg)); 
              ShellExecute(Handle, 'open', PChar(RichEdit1.SelText), 0, 0, SW_SHOWNORMAL); 
            end;
          end;
        end;
      end;
    CM_RECREATEWND:
      begin
        SetRichEditMasks;
      end;
  end; 
end;

赞(0）回复(0）举报 2022-12-23

omqzjyyz2#

对我来说，只有当显示的文本与底层超链接的文本相同时，它才起作用。
我认为我的问题是底层超链接具有属性CFE_HIDDEN，因此不能由EM_EXSETSEL选择。
举个例子，如果我用url http://www.rubbish.com创建一个链接（用WORD），但是它显示文本RUBBISH，尽管所选文本的chrg是11-33，也就是22个字符-与URL长度相同，但该方法返回的实际文本是RUBBISH。
但是，我发现如果使用WM_GETTEXT，则返回整个链接：
超链接“http://www.rubbish.com“垃圾
从中我可以提取基于chrg的URL。
感觉有点笨拙...但很有效。：-）

赞(0）回复(0）举报 2022-12-23

j5fpnvbx3#

你有没有试过用一个精简的应用程序来确保它不是你程序中的其他东西引起的问题？我按照 Delphi 2009中那个网站的步骤操作，点击URL工作得很好。

赞(0）回复(0）举报 2022-12-23