当您将String（* 不可变 *）变量声明为final，并使用编译时常量表达式初始化它时，它也会成为编译时常量表达式，其值由使用它的编译器内联。因此，在第二个代码示例中，内联值后，编译器会将字符串串联转换为：

String concat = "str" + "ing";  // which then becomes `String concat = "string";`

与"string"相比，它将给予true，因为字符串常量是 interned。
来自JLS §4.12.4 -final变量：
基元类型或String类型的变量，即final，用编译时常量表达式初始化（参见15.28节），称为 constant variable。
另见JLS §15.28 -常量表达式：
String类型的编译时常量表达式总是被“interned”，以便使用String#intern()方法共享唯一的示例。
在第一个代码示例中，String变量不是final。因此，它们不是编译时常量表达式。其中的串联操作将延迟到运行时，从而导致创建新的String对象。您可以通过比较两段代码的字节码来验证这一点。
第一个代码示例**（非final版本）**编译为以下字节代码：

Code:
   0:   ldc     #2; //String str
   2:   astore_1
   3:   ldc     #3; //String ing
   5:   astore_2
   6:   new     #4; //class java/lang/StringBuilder
   9:   dup
   10:  invokespecial   #5; //Method java/lang/StringBuilder."<init>":()V
   13:  aload_1
   14:  invokevirtual   #6; //Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
   17:  aload_2
   18:  invokevirtual   #6; //Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
   21:  invokevirtual   #7; //Method java/lang/StringBuilder.toString:()Ljava/lang/String;
   24:  astore_3
   25:  getstatic       #8; //Field java/lang/System.out:Ljava/io/PrintStream;
   28:  aload_3
   29:  ldc     #9; //String string
   31:  if_acmpne       38
   34:  iconst_1
   35:  goto    39
   38:  iconst_0
   39:  invokevirtual   #10; //Method java/io/PrintStream.println:(Z)V
   42:  return

显然，它将str和ing存储在两个单独的变量中，并使用StringBuilder执行连接操作。
而第二个代码示例**（final版本）**如下所示：

Code:
   0:   ldc     #2; //String string
   2:   astore_3
   3:   getstatic       #3; //Field java/lang/System.out:Ljava/io/PrintStream;
   6:   aload_3
   7:   ldc     #2; //String string
   9:   if_acmpne       16
   12:  iconst_1
   13:  goto    17
   16:  iconst_0
   17:  invokevirtual   #4; //Method java/io/PrintStream.println:(Z)V
   20:  return

因此，它直接内联最后一个变量以在编译时创建String string，该变量在步骤0中通过ldc操作加载。然后，在步骤7中通过ldc操作加载第二个字符串文字。它不涉及在运行时创建任何新的String对象。String在编译时是已知的。他们被拘留了。

根据我的研究，所有的final String都是用Java编写的。
所以，如果你真的需要使用==或！=来比较两个String，请确保在进行比较之前调用String.intern（）方法。否则，总是首选String.equals（String）进行String比较。
这意味着如果你调用String.intern()你可以用==运算符比较两个字符串，但是这里String.intern()不是必需的，因为在Java中final String是内部寄存的。
您可以找到有关String.intern（）方法的String comparision using == operator和Javadoc的更多信息。
也可以参考这篇Stackoverflow文章了解更多信息。

如果你看看这些方法

public void noFinal() {
    String str1 = "str";
    String str2 = "ing";
    String concat = str1 + str2;

    System.out.println(concat == "string");
}

public void withFinal() {
    final String str1 = "str";
    final String str2 = "ing";
    String concat = str1 + str2;

    System.out.println(concat == "string");
}

以及使用javap -c ClassWithTheseMethods版本进行反编译后，您将看到

public void noFinal();
    Code:
       0: ldc           #15                 // String str
       2: astore_1      
       3: ldc           #17                 // String ing
       5: astore_2      
       6: new           #19                 // class java/lang/StringBuilder
       9: dup           
      10: aload_1       
      11: invokestatic  #21                 // Method java/lang/String.valueOf:(Ljava/lang/Object;)Ljava/lang/String;
      14: invokespecial #27                 // Method java/lang/StringBuilder."<init>":(Ljava/lang/String;)V
      17: aload_2       
      18: invokevirtual #30                 // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      21: invokevirtual #34                 // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      ...

以及

public void withFinal();
    Code:
       0: ldc           #15                 // String str
       2: astore_1      
       3: ldc           #17                 // String ing
       5: astore_2      
       6: ldc           #44                 // String string
       8: astore_3      
       ...

因此，如果字符串不是最终编译器将不得不使用StringBuilder连接str1和str2，因此

String concat=str1+str2;

将被编译为

String concat = new StringBuilder(str1).append(str2).toString();

这意味着concat将在运行时创建，因此不会来自字符串池。
此外，如果字符串是final，则编译器可以假定它们永远不会更改，因此可以安全地连接其值，而不是使用StringBuilder

String concat = str1 + str2;

可改为

String concat = "str" + "ing";

并连接到

String concat = "string";

这意味着concate将成为字符串常量，该字符串常量将被驻留在字符串池中，然后在if语句中与来自该池的相同字符串常量进行比较。

堆栈和串容器池概念

让我们看看final示例的一些字节代码

Compiled from "Main.java"
public class Main {
  public Main();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public static void main(java.lang.String[]) throws java.lang.Exception;
    Code:
       0: ldc           #2                  // String string
       2: astore_3
       3: getstatic     #3                  // Field java/lang/System.out:Ljava/io/PrintStream;
       6: aload_3
       7: ldc           #2                  // String string
       9: if_acmpne     16
      12: iconst_1
      13: goto          17
      16: iconst_0
      17: invokevirtual #4                  // Method java/io/PrintStream.println:(Z)V
      20: return
}

在0:和2:处，String"string"被压入堆栈（从常量池）并直接存储到局部变量concat中，可以推断编译器在编译时创建（连接）了String"string"本身。
非final字节代码

Compiled from "Main2.java"
public class Main2 {
  public Main2();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public static void main(java.lang.String[]) throws java.lang.Exception;
    Code:
       0: ldc           #2                  // String str
       2: astore_1
       3: ldc           #3                  // String ing
       5: astore_2
       6: new           #4                  // class java/lang/StringBuilder
       9: dup
      10: invokespecial #5                  // Method java/lang/StringBuilder."<init>":()V
      13: aload_1
      14: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/Stri
ngBuilder;
      17: aload_2
      18: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/Stri
ngBuilder;
      21: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      24: astore_3
      25: getstatic     #8                  // Field java/lang/System.out:Ljava/io/PrintStream;
      28: aload_3
      29: ldc           #9                  // String string
      31: if_acmpne     38
      34: iconst_1
      35: goto          39
      38: iconst_0
      39: invokevirtual #10                 // Method java/io/PrintStream.println:(Z)V
      42: return
}

这里有两个String常量，"str"和"ing"，它们需要在运行时与StringBuilder连接。

但是，当您使用Java的String文字表示法创建时，它会自动调用intern（）方法将该对象放入String池中，前提是该对象尚未出现在池中。
为什么期末考试会有不同？

编译器知道final变量永远不会改变，当我们添加这些final变量时，输出将进入字符串池，因为str1 + str2表达式输出也永远不会改变，因此final编译器在输出上述两个final变量后调用inter方法。在非final变量的情况下，编译器不调用intern方法。