实际上，您可以在GCC和MSVC中使用标准的预定义宏。
以下是GCC中的predef宏列表：3.7.1 Standard Predefined Macros
对于MSVC：Predefined Macros
代码可能如下所示：

QString datetime = QStringLiteral(__DATE__) + QStringLiteral(" ") + QStringLiteral(__TIME__);

如果你不能使用预定义的宏，就不要在定义中使用空格，而是用反斜杠将其打包，如下所示：

DEFINES += BUILDDATE=\\\"$$system( date "+%d.%m.%Y_%H:%M:%S" )\\\"

strBldDate.replace(QChar('_'), QChar(' '));

编辑：创建builddatetime.h文件，并将其包含在需要构建版本的任何位置：

#ifndef BUILDDATETIME_H
#define BUILDDATETIME_H

#include <QString>
const QString BUILDV =  QStringLiteral(__DATE__ " " __TIME__);

#endif // BUILDDATETIME_H

在.pro文件中，将builddatetime.h添加到标题（HEADERS += builddatetime.h）和以下行：

buildtimeTarget.target = builddatetime.h
buildtimeTarget.depends = FORCE
buildtimeTarget.commands = touch $$PWD/builddatetime.h
PRE_TARGETDEPS += builddatetime.h
QMAKE_EXTRA_TARGETS += buildtimeTarget

这将触及builddatetime.h，并且包含此头文件的所有cpp文件将在每个构建和运行命令时重新构建。

对于每个想要相同但在windows上的人。使用@Xplatforms解决方案与builddatetime.h文件，但使用不同的命令：

WIN_PWD=$$replace(PWD, /, \\)

buildtimeTarget.target = builddatetime.h
buildtimeTarget.depends = FORCE
buildtimeTarget.commands = copy /b $$WIN_PWD\builddatetime.h+,,$$WIN_PWD\builddatetime.h
PRE_TARGETDEPS += builddatetime.h
QMAKE_EXTRA_TARGETS += buildtimeTarget