这是我从exec获取stdout的首选语法：

def stdout = new ByteArrayOutputStream()
exec{
    commandLine "whoami"
    standardOutput = stdout;
}
println "Output:\n$stdout";

在此找到：http://gradle.1045684.n5.nabble.com/external-process-execution-td1431883.html（请注意，该页面有一处排印错误，提到的是ByteArrayInputStream而不是ByteArrayOutputStream）

这个post描述了如何解析Exec调用的输出，下面你会发现两个运行你的命令的任务。

task setWhoamiProperty {
    doLast {
        new ByteArrayOutputStream().withStream { os ->
            def result = exec {
                executable = 'whoami'
                standardOutput = os
            }
            ext.whoami = os.toString()
        }
    }
}

task setHostnameProperty {
    doLast {
        new ByteArrayOutputStream().withStream { os ->
            def result = exec {
                executable = 'hostname'
                standardOutput = os
            }
            ext.hostname = os.toString()
        }
    }
}

task printBuildInfo {
    dependsOn setWhoamiProperty, setHostnameProperty
    doLast {
         println whoami
         println hostname
    }
}

实际上，有一种更简单的方法可以获得这些信息，而不必调用shell命令。
当前登录用户：System.getProperty('user.name')
主机名：InetAddress.getLocalHost().getHostName()

使用kotlin-dsl：

import java.io.ByteArrayOutputStream

val outputText: String = ByteArrayOutputStream().use { outputStream ->
  project.exec {
    commandLine("whoami")
    standardOutput = outputStream
  }
  outputStream.toString()
}

Groovy在很多情况下允许更简单的实现，所以如果你使用基于Groovy的构建脚本，你可以简单地这样做：

def cmdOutput = "command line".execute().text

摘自Gradle docs for Exec：

task execSomething {
  doFirst {
    exec {
      workingDir '/some/dir'
      commandLine '/some/command', 'arg'

      ...
      //store the output instead of printing to the console:
      standardOutput = new ByteArrayOutputStream()

      //extension method execSomething.output() can be used to obtain the output:
      ext.output = {
        return standardOutput.toString()
      }
    }
  }
}

kotlin-dsl变体

时髦的风格

在buildSrc中：

import org.codehaus.groovy.runtime.ProcessGroovyMethods

fun String.execute(): Process = ProcessGroovyMethods.execute(this)
fun Process.text(): String = ProcessGroovyMethods.getText(this)

build.gradle.kts:

"any command you want".execute().text().trim()

执行样式

在buildSrc中：

import org.gradle.api.Project
import org.gradle.process.ExecSpec
import java.io.ByteArrayOutputStream

fun Project.execWithOutput(spec: ExecSpec.() -> Unit) = ByteArrayOutputStream().use { outputStream ->
    exec {
        this.spec()
        this.standardOutput = outputStream
    }
    outputStream.toString().trim()
}

build.gradle.kts：

val outputText = project.execWithOutput {
    commandLine("whoami")
}

//variable project is actually optional

val outputText = execWithOutput {
    commandLine("whoami")
}