excel 交货天数和交货订单数在两个独立的列中,是否有方法获得订单的汇总统计数据？

wgmfuz8q 于 2023-02-05 发布在其他

关注(0)|答案(1)|浏览(165)

我在解释这个问题时遇到了一些麻烦，所以请原谅我。我也是一个使用excel的新手，所以如果有一个简单的修复，我提前道歉！
我有两列，一列是从0开始连续增加的天数，另一列是交付的订单数，这两列是相互对应的。例如，我已经在下面输入了它的外观。这意味着1天交付100个订单，2天交付150个订单，3天交付800个订单，等等。

是否有方法获得汇总统计数据（平均值，中位数，众数，上四分位数和下四分位数）的天数，它的平均订单得到交付？唯一的方法，我能想到的解决这个问题是手动打卡在“1”100次，“2”150次等到一个新的列，并采取中位数，平均值，上四分位数和下四分位数从，但那似乎效率极低。我会为此使用数据透视表吗？提前谢谢你！
我试着用数据分析插件来做汇总统计，但是没有用，它只给出了每一列的均值、中位数、众数和四分位数，交货天数的中位数是3，订单数的中位数是300。

excel

来源：https://stackoverflow.com/questions/75280446/number-of-days-for-delivery-and-number-of-orders-delivered-in-two-separate-colum

1条答案

按热度按时间

xqnpmsa81#

- 方法1**

平均值就是

=SUMPRODUCT(A2:A6,B2:B6)/SUM(B2:B6)

模式是频率最高的值

=INDEX(A2:A6,MATCH(MAX(B2:B6),B2:B6,0))

四分位数和中位数（或通过改变p值的任何其他四分位数）来自遵循this reference的第一性原理

=LET(p,0.25,
values,A2:A6,
freq,B2:B6,
N,SUM(freq),
h,(N+1)*p,
floorh,FLOOR(h,1),
ceilh,CEILING(h,1),
frac,h-floorh,
cusum,SCAN(0,SEQUENCE(ROWS(values)),LAMBDA(a,c,IF(c=1,0,a+INDEX(freq,c-1)))),
xlower,XLOOKUP(floorh-1,cusum,values,,-1),
xupper,XLOOKUP(ceilh-1,cusum,values,,-1),
xlower+(xupper-xlower)*frac)

- 方法二**

如果您不喜欢这样做，您可以随时这样展开数据：

=AVERAGE(XLOOKUP(SEQUENCE(SUM(B2:B6),1,0),SCAN(0,SEQUENCE(ROWS(A2:A6)),LAMBDA(a,c,IF(c=1,0,INDEX(B2:B6,c-1)+a))),A2:A6,,-1))

=MODE(XLOOKUP(SEQUENCE(SUM(B2:B6),1,0),SCAN(0,SEQUENCE(ROWS(A2:A6)),LAMBDA(a,c,IF(c=1,0,INDEX(B2:B6,c-1)+a))),A2:A6,,-1))

=QUARTILE.EXC(XLOOKUP(SEQUENCE(SUM(B2:B6),1,0),SCAN(0,SEQUENCE(ROWS(A2:A6)),LAMBDA(a,c,IF(c=1,0,INDEX(B2:B6,c-1)+a))),A2:A6,,-1),1)


=MEDIAN(XLOOKUP(SEQUENCE(SUM(B2:B6),1,0),SCAN(0,SEQUENCE(ROWS(A2:A6)),LAMBDA(a,c,IF(c=1,0,INDEX(B2:B6,c-1)+a))),A2:A6,,-1))

以及

=QUARTILE.EXC(XLOOKUP(SEQUENCE(SUM(B2:B6),1,0),SCAN(0,SEQUENCE(ROWS(A2:A6)),LAMBDA(a,c,IF(c=1,0,INDEX(B2:B6,c-1)+a))),A2:A6,,-1),3)

赞(0）回复(0）举报 2023-02-05

我来回答

excel 交货天数和交货订单数在两个独立的列中,是否有方法获得订单的汇总统计数据？

1条答案

相关问题

热门标签

最新问答