试试手动的方式，看看是否行得通.
1.将手机插入计算机，等待其注册为已连接设备
1.在cmd中打开终端，然后使用以下命令
adb tcpip 5555 adb connect（您的设备IP类似）192.168.16.0：5555您的IP位于setting〉about phone〉status中如果您的环境设置正确，现在可以拔出并继续无线调试

只需在最后一个补丁https://developer.android.com/studio?utm_source=android-studio上更新您的大黄蜂
它帮我解决了同样的问题

有时候这是最挑剔的事情，我遇到过GUI连接在会话中无缘无故中断的情况。
我写了一个 bat ，我希望其他人觉得有用。

• 它请求IP。
• 它可能会询问IP详细信息。
• 然后，它要求输入CONNECTION PORT（在最后一个命令中使用，但在提示符出现时不可见）。
• 然后，它要求输入配对代码。
• 然后，它会请求配对端口。

这是密码

@echo off
setlocal enabledelayedexpansion

:start

set useIP=
rem Step 1: Choose IP
echo Menu:
echo    0: Custom IP
  if not exist batconfig.txt (
    echo    1: NO PREVIOUS IP CONFIGURED
  ) else (
    set /p lastIP=<batconfig.txt
    echo    1. Last IP: !lastIP!
  )
echo    2: 10.0.0.---
echo    3: 192.168.1.---
set /p ipOption=Select Option: 

if %ipOption%==0 (
  set /p customIP=Enter custom IP: 
  set useIP=!customIP!
) else if %ipOption%==1 (
  if not exist batconfig.txt (
    echo batconfig.txt not found.
    pause
    goto start
  ) else (
    set /p useIP=<batconfig.txt
    echo Loaded IP: !useIP!
  )
) else if %ipOption%==2 (
  set /p ipPrompt=Enter last segment of IP 10.0.0.---: 
  set useIP=10.0.0.!ipPrompt!
  echo %useIP%
) else if %ipOption%==3 (
  set /p ipPrompt=Enter last segment of IP 192.168.1.---: 
  set useIP=192.168.1.!ipPrompt!
) else (
  echo Invalid selection. Restarting...
  goto start
)

rem Step 2: Connection Port
set /p connectPort=Enter CONNECTION PORT (main screen) for %useIP%: 

rem Step 3: Pairing Code and Port
set /p pairingCode=Enter PAIRING CODE (popup) for %useIP%: 
set /p pairingPort=Enter PAIRING PORT (popup) for %useIP%: 
echo Attempting to connect to %useIP%:!pairingPort!

rem Step 4: Run adb pair command
set error=
echo Executing command... adb pair %useIP%:!pairingPort! !pairingCode!
adb pair %useIP%:!pairingPort! !pairingCode! >error.txt
set error=!errorlevel!
if !error! equ 0 (
  echo Successfully paired with %useIP%:%pairingPort%
  echo %useIP%>batconfig.txt

  echo Executing command... adb connect %useIP%:%connectPort%
  adb connect %useIP%:%connectPort%
) else (
  rem Step 4: Output error message
  set /p error=<error.txt
  echo !error!
)

有时ADB是额外的挑剔，我不得不断开我的手机与WIFI，重新连接，并重新启用无线调试。