按钮之谜

• 当您开始添加按钮时，它们的名称和文本是相同的，例如Button 1、Button 2 ...等。
• 一旦你开始删除和重命名它们并添加新的，它们的文本和名称可能（将）最终会不同。
• 使用以下工具了解您的特定案例中发生了什么。希望您提供反馈，例如 "我的Button 6奇迹般地变成了Button 13，而其文本仍然是Button 6 ..."。

Sub DeMystifyButtons()
    
    Dim ButtonNames()
    ButtonNames = Array("Button 6", "Button 7", "Button 11", "Button 12")
    
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    Dim ws As Worksheet: Set ws = wb.Sheets("Open SO")
    
    Dim btn As Button, i As Long, IsFound As Boolean
    
    Debug.Print "Index", "Name", "Text", "Is Found"
    
    For Each btn In ws.Buttons
        IsFound = IsNumeric(Application.Match(btn.Name, ButtonNames, 0))
        Debug.Print btn.Index, btn.Name, btn.Text, IsFound
    Next btn
    
End Sub

• • 附加内容：列表**

Sub ListAllButtons(ByVal ws As Worksheet)
    If ws.Buttons.Count = 0 Then Exit Sub
    Debug.Print "Index", "Name", "Text"
    Dim btn As Button
    For Each btn In ws.Buttons
        Debug.Print btn.Index, btn.Name, btn.Text
    Next btn
End Sub

• • 附加内容：删除**

Sub DeleteAllButtons(ByVal ws As Worksheet)
    ws.Buttons.Delete
End Sub

• • 附加项：用法**

Sub Test()

    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    Dim ws As Worksheet: Set ws = wb.Sheets("Open SO")

    ListAllButtons ws
    'DeleteAllButtons ws
     
End Sub

• • 编辑**

Sub DeleteByID()

    Dim ButtonIDs(): ButtonIDs = Array("6", "7", "11", "12")

    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    Dim ws As Worksheet: Set ws = wb.Sheets("Open SO")

    DeleteButtonsByID ws, ButtonIDs
     
End Sub

Sub DeleteButtonsByID(ByVal ws As Worksheet, ByVal ButtonIDs As Variant)
    Dim btn As Button
    For Each btn In ws.Buttons
        If IsNumeric(Application.Match(Trim(Right(btn.Name, 2)), ButtonIDs, 0)) _
            Then btn.Delete
    Next btn
End Sub

命令的语法正确。该错误表示（至少）其中一个形状不存在。可能是名称中有打字错误，或者该形状已被删除。
例如，尝试下面的例程，它将删除您指定的所有形状，但如果一个形状不存在（或由于其他原因无法删除），它将只把形状名称写入即时窗口并继续工作。

Sub DeleteShapes(ws As Worksheet, shapeNames)
    Dim shapeName
    For Each shapeName In shapeNames
        On Error Resume Next
        ws.shapes(shapeName).Delete
        If Err.Number <> 0 Then
            Debug.Print "Error when deleting shape '" & shapeName & "': " & Err.Number & " " & Err.Description
        End If
        On Error GoTo 0
    Next
End Sub

例如，您可以使用

DeleteShapes ThisWorkbook.Sheets("Open SO"), _
                Array("Button 6", "Button 7", "Button 11", "Button 12")