我使用了TADOQuery而不是TADOCommand，添加了一个长度为200的计算TStringField（CalcUserAccountControl），并声明了以下类型和常量：

type
  TControlFlags = (  SCRIPT, ACCOUNTDISABLE, HOMEDIR_REQUIRED, LOCKOUT, PASSWD_NOTREQD,
                     PASSWD_CANT_CHANGE, ENCRYPTED_TEXT_PWD_ALLOWED, TEMP_DUPLICATE_ACCOUNT,
                     NORMAL_ACCOUNT, INTERDOMAIN_TRUST_ACCOUNT, WORKSTATION_TRUST_ACCOUNT,
                     SERVER_TRUST_ACCOUNT, DONT_EXPIRE_PASSWORD, MNS_LOGON_ACCOUNT,
                     SMARTCARD_REQUIRED, TRUSTED_FOR_DELEGATION, NOT_DELEGATED,
                     USE_DES_KEY_ONLY, DONT_REQ_PREAUTH, PASSWORD_EXPIRED,
                     TRUSTED_TO_AUTH_FOR_DELEGATION, PARTIAL_SECRETS_ACCOUNT);
...
const
  //Bit position of every flag
  BitControlFlag : Array [TControlFlags] of Integer =
  (0, 1, 3, 4, 5, 6, 7, 8, 9, 11, 12, 13, 16, 17, 18, 19, 20, 21, 22, 23, 24, 26);
  //Description of every flag
  StrControlFlag : Array [TControlFlags] of string =
  ('|SCRIPT', '|ACCOUNTDISABLE', '|HOMEDIR_REQUIRED', '|LOCKOUT', '|PASSWD_NOTREQD',
   '|PASSWD_CANT_CHANGE', '|ENCRYPTED_TEXT_PWD_ALLOWED', '|TEMP_DUPLICATE_ACCOUNT',
   '|NORMAL_ACCOUNT', '|INTERDOMAIN_TRUST_ACCOUNT', '|WORKSTATION_TRUST_ACCOUNT',
   '|SERVER_TRUST_ACCOUNT', '|DONT_EXPIRE_PASSWORD', '|MNS_LOGON_ACCOUNT',
   '|SMARTCARD_REQUIRED', '|TRUSTED_FOR_DELEGATION', '|NOT_DELEGATED',
   '|USE_DES_KEY_ONLY', '|DONT_REQ_PREAUTH', '|PASSWORD_EXPIRED',
   '|TRUSTED_TO_AUTH_FOR_DELEGATION', '|PARTIAL_SECRETS_ACCOUNT');

...

之后，在TADOQuery的OnCalcFields方法中，只需要检查查询中UserAccountControl字段的位即可。

procedure TForm2.TADOQuery1CalcFields(DataSet: TDataSet);
var
  CurrentUAC : Integer;
  StrUAC : String;
  ControlFlags : TControlFlags;
begin
  CurrentUAC := TADOQuery1.FieldByName('userAccountControl').AsInteger;

  for var aControlFlag := low(ControlFlags) to high(ControlFlags) do
    if CurrentUAC and (1 shl BitControlFlag[aControlFlag]) <> 0 then
      strUAC := strUAC + StrControlFlag[aControlFlag];

  TADOQuery1.FieldByName('CalcUserAccountControl').Value := strUAC;
end;

在计算字段中，我得到了一个字符串，其中包含UserAccountControl的每个标志，如下所示：

|PASSWD_NOTREQD|WORKSTATION_TRUST_ACCOUNT
|WORKSTATION_TRUST_ACCOUNT|DONT_EXPIRE_PASSWORD
|ACCOUNTDISABLE|PASSWD_NOTREQD|WORKSTATION_TRUST_ACCOUNT

记住这一点，您可以使用CalculatedField值来筛选结果集，以便仅显示所需的UserAccountControl标志。

使用TADOQuery，您可以设置Filtered：= True并添加OnFilterRecord方法，以便仅获取UserAcountControl字段中具有特定位的记录，如以下代码所示：

procedure TForm2.TADOQuery1FilterRecord(DataSet: TDataSet; var Accept: Boolean);
var
  CurrentUAC : Integer;
const
  ACCOUNTDISABLE = 1; //the bit 1 has the ACCOUNTDISABLE flag 
begin
  CurrentUAC := TADOQuery1.FieldByName('userAccountControl').AsInteger;
  //Accept only those records without the ACCOUNTDISABLE flag
  Accept := CurrentUAC and (1 shl ACCOUNTDISABLE) = 0; 
end;