为了将指针视为数组，请确保{$POINTERMATH ON}已启用。PByte已经启用了{$POINTERMATH ON}（不要直接使用^Byte），但默认情况下大多数指针类型未启用。
试试这样的方法：

{$POINTERMATH ON}
var
  P1 : PByte;
  w, byteoffset : Word;
begin 
  P1 := SomeGetMemVar;
  byteoffset := 8;
  w := PWord(@P1[byteoffset])^;
  //or:
  w := PWord(P1+byteoffset)^;
end;

或者，使用Move()而不是强制转换指针：

var
  P1 : PByte;
  w, byteoffset : Word;
begin 
  P1 := SomeGetMemVar;
  byteoffset := 8;
  Move(P1[byteoffset], w, SizeOf(w));
  //or:
  Move((P1+byteoffset)^, w, SizeOf(w));
end;

对于不支持{$POINTERMATH}的旧编译器，可以类型转换为PAnsiChar（默认情况下总是支持指针数学）：

var
  P1 : PByte;
  P2: PAnsiChar;
  w, byteoffset : Word;
begin 
  P1 := SomeGetMemVar;
  P2 := PAnsiChar(P1);
  byteoffset := 8;
  w := PWord(@P2[byteoffset])^;
  //or:
  w := PWord(P2+byteoffset)^;
end;

或者，只需手动递增PByte指针：

var
  P1, P2 : PByte;
  w, byteoffset : Word;
begin 
  P1 := SomeGetMemVar;
  byteoffset := 8;
  P2 := P1;
  Inc(P2, byteoffset);
  w := PWord(P2)^;
end;

如果你的例子就是你想要做的，也就是简单地提取一个单词的一个字节，你就不需要做所有的指针操作。

uses System.SysUtils;
type WordPtr = ^WordRec;
var w:  word;
    p1: WordPtr;
begin
  p1=GetSomeMemVar;
  w:=p1.Hi;
end;

WordRec是一个记录，在一个单词的空间里有两个字节字段，这样你就可以访问单词的每个字节。SysUtils还有LongRec和Int64Rec，它们都有变体部分，这样你就可以访问单独的字节或单独的单词等，或者把它们当作数组。你总是可以创建自己的类似记录。
如果要继续使用指针，请参见https://docwiki.embarcadero.com/RADStudio/Sydney/en/Pointer_Math_%28Delphi%29