下面是我的例子：

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, System.IOUtils, System.StrUtils;
var
  Dir,
  c   :  string;
begin
  try
    Dir := 'C:\abc'; //The search directory
    for c in TDirectory.GetFiles(Dir, '*.*',
         function (const Path: string; const SearchRec: TSearchRec): Boolean
         begin
           Result := IndexText(ExtractFileExt(SearchRec.Name).ToLower, ['.zip', '.bak']) >= 0;
         end) do
    begin
      writeln(c);
    end;
    readln(c);
  except
     on E: Exception do
        Writeln(E.ClassName, ': ', E.Message);
  end;
end.

如果你有一个现代的 Delphi ，你可以

FOR VAR FileName IN TDirectory.GetFiles('*.bak')+TDirectory.GetFiles('*.zip') DO ...

FileName将是当前目录中所有 *.巴克和 *.zip的名称（一次一个）。如果您需要特定的目录，您可以

FOR VAR FileName IN TDirectory.GetFiles(TPath.Combine(Archive,'*.bak'))+TDirectory.GetFiles(TPath.Combine(Archive,'*.zip')) DO ...

在所有情况下，您都需要

USES System.IOUtils;

如果你想使用Find(First|Next)()搜索多个文件扩展名，那么你必须使用通配符掩码*.*，然后根据需要过滤结果，例如：

var
  s: TSearchRec;
  ext: string

if FindFirst(Archive + '*.*', faNormal or faReadOnly, s) = 0 then
try
  repeat
    if (s.Attr and faDirectory) <> 0 then
      Continue;
    ext := ExtractFileExt(s.Name);
    if SameText(ext, '.bak') or SameText(ext, '.zip') then
    begin
      // use file as needed...
    end;
  until FindNext(s) <> 0;
finally
  FindClose(s);
end;