这里有一个一步到位的方法：

Sub FormatOutput()
    Const NUM_PTS As Long = 8 'points per curve
    Dim wb As Workbook, wsSrc As Worksheet, wsDest As Worksheet
    Dim rngConcs As Range, rngData As Range, cDest As Range, col As Long
    Dim rwDest As Range, r As Long, wellRow As Long, wellCol As Long
    
    Set wb = ActiveWorkbook
    Set wsSrc = ActiveSheet
    Set wsDest = wb.Worksheets("listing") 'for example
    Set rwDest = wsDest.Rows(2)
    
    Set rngConcs = wsSrc.Range("A2").Resize(NUM_PTS)
    wellCol = 1
    Do While Application.CountA(rngConcs) > 0 'loop down the concentration column
        For col = 1 To 20                'loop across the readout columns
            Set rngData = rngConcs.Offset(0, col)
            If Application.CountA(rngData) > 0 Then 'any readout data here?
                For wellRow = 1 To NUM_PTS
                    rwDest.Cells(1).Value = rngConcs.Cells(wellRow).Value
                    rwDest.Cells(2).Value = WellLabel(wellRow, wellCol)
                    rwDest.Cells(3).Value = rngData.Cells(wellRow).Value
                    Set rwDest = rwDest.Offset(1)  'next row on output sheet
                Next wellRow
                wellCol = wellCol + 1 'next plate column
            End If
        Next col
    
        Set rngConcs = rngConcs.Offset(NUM_PTS + 1) 'next concs block (one blank line)
    Loop
End Sub

'return a well label given row and column number
Function WellLabel(rw As Long, col As Long) As String
    WellLabel = Chr(64 + rw) & Format(col, "00")
End Function