尝试单独处理这些行。

Sub changeDQ()

    Const ForReading = 1
    Const ForWriting = 2
    Const fileSpec = "31_12_2022.xls"

    Dim fso, tsIn, tsOut, s As String, n As Long
    Dim t0 As Single: t0 = Timer
    
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set tsIn = fso.OpenTextFile(fileSpec, ForReading, Format:=-2)
    Set tsOut = fso.OpenTextFile("~" & fileSpec, ForWriting, _
                Create:=True, Format:=-2) ' -2=system default -1=Unicode
    
    Do While tsIn.AtEndOfStream = False
        s = tsIn.ReadLine
        tsOut.WriteLine Replace(s, Chr(34), "")
        n = n + 1
    Loop
    tsIn.Close
    tsOut.Close
    MsgBox n & " lines processed from " & fileSpec, _
           vbInformation, Format(Timer - t0, "0.0 secs")
   
End Sub

在新的空白工作簿中使用此脚本分析文件。输入100作为字节数，并选择带有对话框的文件。

Sub CheckFile()

    Dim BYTES As Long, filename As String
    
    BYTES = InputBox("Number of bytes", "Bytes")
    With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = False
        .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        filename = .SelectedItems(1)
    End With

    Dim objStreamIn, i, v
    Set objStreamIn = CreateObject("ADODB.Stream")
    With objStreamIn
        .Type = 1 'adTypeBinary
        .Open
        .LoadFromFile filename
        .Position = 0
        v = .Read(BYTES)
    End With
    
    With Sheet1
        .Cells.Clear
        .Range("A1:D1") = Array("Pos", "Dec", "Hex", "Chr")
        For i = 2 To BYTES + 1
            .Cells(i, 1) = i - 1
            .Cells(i, 2) = CLng(v(i - 2))
            .Cells(i, 3) = Hex(v(i - 2))
            .Cells(i, 4) = ChrW(v(i - 2))
        Next
    End With
    
    MsgBox BYTES & " bytes read to sheet1 from " & filename

End Sub

尝试此操作以进一步分析文件。

Sub AnalyseFile()
   
    Dim a() As Byte, i As Long, n As Long, filename As String
    Dim s As String, t0 As Single: t0 = Timer
    
    With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = False
        .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        filename = .SelectedItems(1)
    End With
    
    With CreateObject("ADODB.Stream")
         .Open
         .Type = 1  ' adTypeBinary
         .LoadFromFile filename
         a = .Read
         .Close
    End With
   
    For i = 0 To UBound(a)
        If a(i) = 34 Then
           n = n + 1
           a(i) = 32
        End If
    Next
    s = filename & vbLf & Format(n, "#,###") & " ""'s found and replaced in  " & _
        Format(i, "#,### bytes")
    MsgBox s, vbInformation, Format(Timer - t0, "0.0 secs")
    
    Dim newfile
    newfile = "test_" & Format(Now, "yyyymmdd_hhmmss") & ".xls"
    With CreateObject("ADODB.Stream")
         .Open
         .Type = 1  ' adTypeBinary
         .Write a
         .SaveToFile newfile
         .Close
    End With
    MsgBox "new file created: " & newfile
  
End Sub