使用CreateProcess而不是SheelExecute似乎可以解决查找句柄的问题。

function TfHostApplication.StartApplication(fn: string): Cardinal;
var
  StartupInfo: TStartupInfo;
  Command: string;
begin
  Result := 0;
  FillChar(StartupInfo, SizeOf(TStartupInfo), 0);
  StartupInfo.cb := SizeOf(TStartupInfo);
  StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
  StartupInfo.wShowWindow := SW_HIDE;
  Command := '"' + fn + '"';
  if CreateProcess(nil, PChar(Command), nil, nil, False, 0, nil, nil, StartupInfo, ProcessInfo) then
  begin
    ProcessHandle := ProcessInfo.hProcess;
    Result := ProcessInfo.dwProcessId;
  end;
end;

procedure TfHostApplication.HostApplication(fn: string);
var
  Title: string;
begin
  process_id := StartApplication(fn);
  if process_id > 0 then
  begin
    // Wait for it to become ideal i.e. finished loading
    WaitForInputIdle(ProcessInfo.hProcess, 5000);
    WaitForSingleObject(ProcessInfo.hProcess, 5000);
    // Get the list of window handles for this process
    AppWindowHandles.Clear;
    SelectedWindowHandle := Windows.FindWindow(PWideChar(TPath.GetFileNameWithoutExtension(FAppFileName)), nil );
    if SelectedWindowHandle <> 0 then
      ShowAppInWindow
    else
    begin
      EnumWindows(@enum_windows_callback, NativeInt(Self));
      if AppWindowHandles.Count > 1 then
      begin
        // if there is more than 1 window then display a list for the user to choose
        lbWindows.Items.Clear;
        var def := 0;
        for var hwd in AppWindowHandles do
        begin
          var Len := GetWindowTextLength(hwd) + 1;
          SetLength(Title, Len);
          GetWindowText(hwd, PChar(Title), Len);
          Title := Trim(Title);
          lbWindows.Items.Add(Title);
        end;
        // Check to see if the selected window is already in the parameters
        var sIdx := lbWindows.Items.IndexOf(FSelectedWindowName);
        if (sIdx > -1) and (sIdx < AppWindowHandles.Count) then
        begin
          SelectedWindowHandle := AppWindowHandles[sIdx];
          ShowAppInWindow;
        end
        else
        begin
          PanelSel.Visible := true;
          PanelSel.align := alClient;
        end;
      end
      else if AppWindowHandles.Count > 0 then
      begin
        // if there is only 1 window then just use this.
        SelectedWindowHandle := AppWindowHandles[0];
        ShowAppInWindow;
      end
      else
        DoCloseView;
    end;
  end;
end;

procedure TfHostApplication.lbWindowsClick(Sender: TObject);
begin
  inherited;
  PanelSel.Visible := false;
  if (lbWindows.ItemIndex > -1) and (lbWindows.ItemIndex < AppWindowHandles.Count) then
  begin
    SelectedWindowHandle := AppWindowHandles[lbWindows.ItemIndex];
    SelectedWindowName := lbWindows.Items[lbWindows.ItemIndex];
    ShowAppInWindow;
  end;
end;

procedure TfHostApplication.ShowAppInWindow;
begin
  // Set the window parent
  Windows.SetParent(SelectedWindowHandle, Handle );

  var Style := GetWindowLongPtr(SelectedWindowHandle, GWL_STYLE);
  Style := Style and (not (WS_BORDER + WS_DLGFRAME + WS_THICKFRAME));
  SetWindowLongPtr(SelectedWindowHandle, GWL_STYLE, Style);

  Resize;
  ShowWindow(SelectedWindowHandle, SW_SHOW);
  BringWindowToTop(SelectedWindowHandle);
end;

例如，如果我启动notepad.exe，下面的例程找不到任何与进程ID匹配的窗口句柄
原因是在64位版本的Windows上，默认情况下会启动64位版本的记事本。由于您的程序是32位的，因此您无法从任何64位应用程序/进程访问进程信息。
您需要使用64位版本的应用程序才能从64位应用程序中检索进程信息。
注意：您可以手动启动位于\Windows\SysWOW64文件夹中的32位版本的记事本。