我发现了这个变通方案，基本上可以防止在菜单选择时调用“reset-prompt”：

TRAPALRM() {
    if [ "$WIDGET" != "complete-word" ]; then
        zle reset-prompt
    fi
}

请注意，complete-word对您来说可能不同;我在TRAPALRM调用中用echo $WIDGET找到了它。

我对此问题的解决方案是同时检查$WIDGET和$_lastcomp[insert]值，以便更精确地了解menu-select此时是否处于活动状态。

autoload -U is-at-least
TMOUT=1
if is-at-least 5.1; then
    # avoid menuselect to be cleared by reset-prompt
    redraw_tmout() {
        [ "$WIDGET" = "expand-or-complete" ] && [[ "$_lastcomp[insert]" =~ "^automenu$|^menu:" ]] || zle reset-prompt
    }
else
    # evaluating $WIDGET in TMOUT may crash :(
    redraw_tmout() { zle reset-prompt }
fi
TRAPALRM() { redraw_tmout }

“expand-or-complete”可能是“complete-word”或者其他什么，这取决于绑定到tab键的键，可以通过bindkey "^I"命令检查。

一个让你在所有情况下都能使用reset-prompt的变通方法是根本不使用中断。在.zshrc中：

function _clear-line {
    zle -K viins
    zle reset-prompt
    zle kill-whole-line
}
zle -N _clear-line
precmd() {
    # Bind ctrl-b to the interrupt signal.
    stty intr \^b
    bindkey '^C' _clear-line
    bindkey -M vicmd '^C' _clear-line
    # Optionally, react differently from inside menuselect :
    #bindkey -M menuselect '^C' undo
}
preexec() {
    # Restore the ctrl-c binding.
    stty intr \^c
}

您需要了解stty如何调用您的ALRM信号，以使其适应您的用例。