已对您提供的数据和代码进行快速测试，没有任何问题。但是，代码存在问题：虽然您将特定工作表分配给变量，但仍继续使用 ActiveSheet。很可能此工作表不是包含示例数据的工作表，并且可能包含导致类型不匹配错误的数据。
在Excel中编写VBA程序时，应始终准确限定要在哪个工作表上工作。一种方法是使用With-语句。注意在Cells、Range、Rows和Columns的 * 每个 * 示例之前添加一个点-以告知VBA您正在引用With-语句的对象。

Sub insertrow()
    With ThisWorkbook.Sheets("Sheet2")
        Dim Last As Long, i As Long
        Last = .Cells(.Rows.Count, "A").End(xlUp).Row
        For i = Last To 1 Step -1
            If (.Cells(i, "A").Value) Like "*vote*" _
            And (.Cells(i + 1, "A").Value) <> "Accepted" Then
                .Cells(i + 1, "A").EntireRow.Insert
            End If
        Next i
    End With
End Sub

或者，如果你更喜欢这样：

Sub insertrow()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("Sheet2") 
    
    Dim Last As Long, i As Long
    Last = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    For i = Last To 1 Step -1
        If (ws.Cells(i, "A").Value) Like "*vote*" _
        And (ws.Cells(i + 1, "A").Value) <> "Accepted" Then
            ws.Cells(i + 1, "A").EntireRow.Insert
        End If
    Next i
End Sub

类型不匹配之类的错误通常可以通过使用调试器检查相关数据（在本例中为2个单元格的内容）来很容易地发现。