这不是一个小问题--当然不适合刚开始学习XSLT的人。
我会这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <result>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="normalize-space(raw)"/>
        </xsl:call-template>
    </result>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="','"/>
    <xsl:variable name="token">
        <xsl:choose>
            <xsl:when test="substring($text, 1, 1) = '&quot;'">
                 <xsl:value-of select="substring-before(substring-after($text, '&quot;'), '&quot;')"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="substring-before(concat($text, $delimiter), $delimiter)"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <xsl:if test="normalize-space($token)">         
        <token>
            <xsl:value-of select="$token"/>
        </token>
    </xsl:if>
    <xsl:if test="contains($text, $delimiter)">
        <!-- recursive call -->
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text">
                <xsl:choose>
                    <xsl:when test="substring($text, 1, 1) = '&quot;'">
                         <xsl:value-of select="substring-after(substring-after($text, '&quot;'), '&quot;')"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="substring-after($text, $delimiter)"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:with-param>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

请注意，这并不处理转义引号。
有一些替代方法建议here;我还没测试过