我做错了什么？
从字符串中给定的开始位置，您将找到

• 第一个逗号
• 然后，如果在整个剩余的字符串中没有逗号，则查找下一个冒号;
• 然后，如果在整个剩余的字符串中没有逗号或冒号，则会找到下一个分号;
• 然后，如果在整个剩余字符串中没有逗号、冒号或分号，则查找下一个管道字符;
• 然后你从你找到的字符开始重新查找。

如果你有字符串a|b;c:d,e，那么你匹配的第一个分隔符将是逗号，第一个术语将是a|b;c:d，第二个术语是e;你不会在多个分隔符上分割字符串，除非它们都是按照,然后:然后;然后|的顺序。
此外：

• 不需要对象表类型;您可以使用TABLE OF VARCHAR2(4000)，或者如果每个术语可能大于4000字节，则可以使用TABLE OF CLOB。
• 您使用的是一个非流水线函数，它需要解析整个字符串并在内存中生成整个集合;相反，您可以使用管道函数，它将在找到行时对其进行管道传输，并且可能不需要在内存中保存整个集合。

这是我为earlier question创建的一个函数，它由一个分隔符分隔：

CREATE TYPE clob_table AS TABLE OF CLOB;

CREATE FUNCTION split_clob(
  p_value     IN CLOB,
  p_delimiter IN VARCHAR2 DEFAULT ','
) RETURN clob_table PIPELINED
IS
  v_start  PLS_INTEGER;
  v_next   PLS_INTEGER;
  v_len    PLS_INTEGER;
BEGIN
  v_start := 1;
  LOOP
    v_next := DBMS_LOB.INSTR( p_value, p_delimiter, v_start );
    v_len  := CASE v_next WHEN 0 THEN LENGTH( p_value ) + 1 ELSE v_next END - v_start;
    PIPE ROW ( SUBSTR( p_value, v_start, v_len ) );
    EXIT WHEN v_next = 0;
    v_start := v_next + LENGTH(p_delimiter);
  END LOOP;
END;
/

如果您想将其更改为多个分隔符（并确保每个术语将为4000个字符或更少），则：

CREATE TYPE varchar2_4000_table AS TABLE OF VARCHAR2(4000);

CREATE FUNCTION split_clob(
  p_value     IN CLOB
) RETURN varchar2_4000_table PIPELINED
IS
  v_start  PLS_INTEGER;
  v_next   PLS_INTEGER;
  v_delim  PLS_INTEGER;
  v_len    PLS_INTEGER;
BEGIN
  v_start := 1;
  LOOP
    v_next  := 0;
    v_delim := DBMS_LOB.INSTR( p_value, ',', v_start );
    IF v_delim > 0 AND (v_next = 0 OR v_delim < v_next) THEN
      v_next := v_delim;
    END IF;
    v_delim := DBMS_LOB.INSTR( p_value, ':', v_start );
    IF v_delim > 0 AND (v_next = 0 OR v_delim < v_next) THEN
      v_next := v_delim;
    END IF;
    v_delim := DBMS_LOB.INSTR( p_value, ';', v_start );
    IF v_delim > 0 AND (v_next = 0 OR v_delim < v_next) THEN
      v_next := v_delim;
    END IF;
    v_delim := DBMS_LOB.INSTR( p_value, '|', v_start );
    IF v_delim > 0 AND (v_next = 0 OR v_delim < v_next) THEN
      v_next := v_delim;
    END IF;

    v_len := CASE v_next WHEN 0 THEN LENGTH( p_value ) + 1 ELSE v_next END - v_start;
    PIPE ROW ( SUBSTR( p_value, v_start, v_len ) );
    EXIT WHEN v_next = 0;
    v_start := v_next + 1;
  END LOOP;
END;
/

然后：

SELECT *
FROM   split_clob('abc,ghj,yut')

输出：
| 列值|
| --------------|
| ABC|
| ghj|
| 尤特|
以及：

SELECT *
FROM   split_clob('a|b;c:d,e')

输出：
| 列值|
| --------------|
| 一种|
| B|
| c|
| d|
| e|

• 注意：在早期的Oracle版本中，您需要使用SELECT * FROM TABLE(split_clob(:varaible))，但在更高版本中，表集合表达式语法是可选的，可以省略（正如您所做的那样）。*

fiddle

这或多或少是好的，你只是叫它在一个错误的方式。

SQL> variable patrik clob;
SQL> exec :patrik := 'abc,ghj,yut';

PL/SQL procedure successfully completed.

SQL> select * from table(patrik_split_clob(:patrik));

VALUE
--------------------------------------------------------------------------------
abc
ghj
yut

SQL>