我把问题问'* 我如何合并导入语句 *'，它说它如何试图编写一个模块来实现他们所示的所需导入语句，但他们如何遇到微妙的问题。（他们一定是说错了，所以这看起来像是一个软件推荐的问题，他们准备编辑这个问题，纠正这个印象。）
无论如何，问题中所示的期望的导入/pragma语句让我觉得是不可能的--首先，如何适应导入列表，当然这些列表在这些模块中可能会有所不同？一旦我们开始了，那么pragma呢？等等
编写一个组装导入语句的模块实际上确实很棘手，因为不能只是堆积这些导入语句。但他们已经做到了--参见Import::Into。
来自概要

package My::MultiExporter;

use Import::Into;

sub import {
  my $target = caller;
  Thing1->import::into($target);
  Thing2->import::into($target, qw(import arguments));
}

# etc -- there's way, way more

然后你在你的程序中use My ::MultiExporter;。
这里有一个草图，也许更重要的是，组装模块

package LoadModules;

use warnings;
use strict;
use feature 'say';

use Import::Into;

# Initializing this hash to all supported keys also serves as documentation
my %arg = map { $_ => '' } qw(base utils extras file all); #etc

sub import
{
    my ($pack, @args) = @_;

    %arg = map { $_ => 1 } @args;

    my $target = caller;

    warnings ->import::into($target);
    strict   ->import::into($target);
    feature  ->import::into($target, ':5.10');

    if ($arg{base}) {
        Getopt::Long ->import::into($target);
        Const::Fast  ->import::into($target);
        Data::Dump   ->import::into($target, qw(dd pp));
    }
    
    if ($arg{utils}) {
        List::Util      ->import::into($target, qw(min max));
        List::MoreUtils ->import::into($target, qw(any all none uniq));
    }

    # ... etc ...
}

1;

然后，我们会加载想要的bundle，比如use LoadModules qw(base utils);等。
为了更进一步，让subs加载bundle，这样就可以在不重复代码的情况下组合选项

sub import {
   ...

   _load_base($target)  if $arg{base};
   _load_utils($target) if $arg{utils};

   if ($arg{all}) { 
      _load_base($target);
      _load_utils($target);
      ...
   }
}

sub _load_base {
    my ($target) = @_;
    Getopt::Long ->import::into($target);
    Const::Fast  ->import::into($target);
    Data::Dump   ->import::into($target, qw(dd pp));
}
...

当然还有其他的方法来组织论点;或者仅仅通过经由调度表加载它们来使它们的处理自动化。
这种方法在程序中缺少导入符号的列表，但这是一个一直存在的难题，即如何最好地简化导入语句，同时又对导入进行文档化。
上面的代码是一个草图，需要工作，但希望它是有用的。