存在许多方法来确定滤波器范围中的滤波元素的数量和/或存在。下面是其中的一些

Sub CheckFilter()
    Dim af As AutoFilter, filter_body_range As Range, rng_to_copy As Range
    
    Set af = ThisWorkbook.Sheets(1).AutoFilter
    Set filter_body_range = Intersect(af.Range, af.Range.Offset(1))
    
    ' option 1
    Set rng_to_copy = Nothing
    On Error Resume Next
    Set rng_to_copy = filter_body_range.SpecialCells(xlCellTypeVisible)
    On Error GoTo 0
    If Not rng_to_copy Is Nothing Then
        rng_to_copy.Copy
        Debug.Print "Visible rows in the filter range has been copied: address " & rng_to_copy.Address
        ' paste to the target place
    End If
    
    'option 2
    m = Application.Match(1, filter_body_range.Columns(5), 0)
    If IsNumeric(m) Then
        Debug.Print "The 5 column has value 1"
        ' your code to copy/paste
    End If
    
    ' option 3
    filtered_rows = 0
    On Error Resume Next ' switch off system error handling: if no xlCellTypeVisible cells, error occurs
    filtered_rows = filter_body_range.Columns(1).SpecialCells(xlCellTypeVisible).Count
    On Error GoTo 0 'switch on system error handling
    If filtered_rows > 0 Then
        Debug.Print "Filtered range has " & filtered_rows & " visible rows"
        ' your code to copy/paste
    End If
End Sub

图纸：

Visible rows in the filter range has been copied: address $C$7:$L$7,$C$13:$L$17,$C$24:$L$26
The 5 column has value 1
Filtered range has 9 visible rows