使用Range.Find两次：

Sub CincoDeMayo()
    Dim ws As Worksheet
    Set ws = Workbooks("doc_flow_report.xlsx").Worksheets("Sheet1")
    
    Dim startCell As Range
    Set startCell = ws.Range("B:B").Find( _
        What:=0, LookIn:=xlValues, _
        LookAt:=xlWhole, SearchDirection:=xlNext)
    
    Dim endCell As Range
    Set endCell = ws.Range("P:P").Find( _
        What:=0, LookIn:=xlValues, _
        LookAt:=xlWhole, SearchDirection:=xlPrevious)
    
    If Not startCell Is Nothing And Not endCell Is Nothing Then
        ws.Range(startCell, endCell).EntireRow.Delete
        ' or change .Delete to .ClearContents
    End If
End Sub

请注意，第一个Find开始搜索 after cell B1。根据您的描述，这应该不是问题：“0值通常从第50行左右开始。”

清除范围

• 您可以使用更高效的（与此无关：只有一个匹配）Application.Match来确定单个列中匹配（找到）值的行索引。

Sub RemoveTrailingZeros()

    Dim wb As Workbook
    On Error Resume Next
        Set wb = Workbooks("doc_flow_report.xlsx")
    On Error GoTo 0
    If wb Is Nothing Then
        MsgBox "The workbook is not open.", vbCritical
        Exit Sub
    End If
    
    Dim ws As Worksheet: Set ws = wb.Sheets("Sheet1")
    
    Dim rg As Range
    With ws.Range("A1").CurrentRegion ' nice data: no empty rows or columns
    'With ws.UsedRange ' nothing but the relevant data is in the worksheet
        Set rg = .Resize(.Rows.Count - 1).Offset(1) ' exclude headers
    End With
    
    Dim mrIndex: mrIndex = Application.Match(0, rg.Columns(2), 0)
    If IsError(mrIndex) Then
        MsgBox "No zeros found.", vbCritical
        Exit Sub
    End If
    
    Dim fCell As Range: Set fCell = ws.Cells(mrIndex + 1, "A")
    Dim lCell As Range: Set lCell = rg.Cells(rg.Cells.CountLarge)
    
    Dim crg As Range: Set crg = ws.Range(fCell, lCell)
    
    crg.Clear
    
    MsgBox "Trailing zeros removed.", vbInformation
    
End Sub