如果您只熟悉拖放编程，而不太了解对象或其他单元，那么您需要熟悉使用对象，而不是自动创建的表单和您放入其中的组件。
此链接处的代码是一个完整的单元。您需要在项目中创建一个新的单元（File > New > Unit）。它看起来像这样：

unit Unit1;

interface

implementation

end.

现在，当您保存单元时，单元的名称将自动更改为文件名（不带扩展名），如下所示：

unit MahUSB;

interface

implementation

end.

在本例中，您应该使用与您尝试使用的源相同的单元名称。将单元保存为“MahUSB.pas”，并且应该与项目的其余部分位于同一个文件夹中（或其他地方，只是一个建议）。复制/粘贴该网站上的所有代码，并立即替换本单元中的所有内容。
现在，为了实际使用它，您需要创建此对象的示例。只有一个例子（我说，只是因为看起来，没有必要超过一个）。

非常重要：既然你对物体不熟悉，让我快速解释一下。需要创建对象才能工作。同时，任何被创造出来的东西，在你完成它的时候，也需要被释放。在本例中，我们将在应用程序启动时创建此对象，并在应用程序关闭时释放该对象。

现在，在您的MAIN FORM（不是任何其他表单）上，您需要为OnCreate和OnDestroy放置一个事件处理程序。您还需要声明一个变量来表示此对象。在主窗体的声明中，添加一个具有此对象类型的变量“USB”。确保它在“私人”或“公共”部分下，任何一个都可以。同时确保在uses子句中声明了主单元顶部的“MahUSB”单元。
在主窗体中声明对象：

type
  TForm1 = class(TForm)
  private
    USB: TUsbClass;
  public

  end;

在应用启动/关闭时创建/释放对象：

procedure TForm1.FormCreate(Sender: TObject);
  begin
    USB:= TUsbClass.Create;
  end;

  procedure TForm1.FormDestroy(Sender: TObject);
  begin
    if assigned(USB) then USB.Free;
  end;

现在我们还没结束现在我们需要添加事件处理程序。请注意，在您得到的这个单元的顶部，有两个类型，名为TOnDevVolumeEvent和TOnUsbChangeEvent。这些是事件类型。事件处理程序中的参数必须与这些类型中声明的参数相同。所以现在在你的主窗体中，声明这些事件处理程序过程。。

type
    TForm1 = class(TForm)
      procedure FormCreate(Sender: TObject);
      procedure FormDestroy(Sender: TObject);
    private
      USB: TUsbClass;
      procedure VolumeEvent(const bInserted : boolean; const sDrive : string);
      procedure ChangeEvent(const bInserted : boolean;
        const ADevType,ADriverName, AFriendlyName : string);
    public

    end;

在这之前我们还有一件事要做。USB对象需要知道要使用什么事件处理程序，因此，我们需要将这些过程分配给事件。在创建表单时，我们需要分配这些事件...

procedure TForm1.FormCreate(Sender: TObject);
    begin
      USB:= TUsbClass.Create;
      USB.OnUsbChange:= Self.ChangeEvent;
      USB.OnDevVolume:= Self.VolumeEvent;
    end;

当一切都说了和做了，你的主表单单元应该看起来像这样：

unit uUSBTest;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, MahUSB;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    USB: TUsbClass;
    procedure VolumeEvent(const bInserted : boolean; const sDrive : string);
    procedure ChangeEvent(const bInserted : boolean;
      const ADevType,ADriverName, AFriendlyName : string);
  public

  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.ChangeEvent(const bInserted: boolean; const ADevType,
  ADriverName, AFriendlyName: string);
begin
  ShowMessage('Change event for "'+AFriendlyName+'"');
end;

procedure TForm1.VolumeEvent(const bInserted: boolean;
  const sDrive: string);
begin
  ShowMessage('Volume event for "'+sDrive+'\"');
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  USB:= TUsbClass.Create;
  USB.OnUsbChange:= Self.ChangeEvent;
  USB.OnDevVolume:= Self.VolumeEvent;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if assigned(USB) then USB.Free;
end;

end.

你就在这里！您将拥有这两个事件处理程序过程，您可以在其中进一步处理这两个事件中的任何一个。