也许像这样的东西。。

Sub standardfilter()

    Dim resultsDictionary As Object
    Dim ws As Worksheet
    Dim tbl As ListObject
    Dim rng As Range
    Dim rw As Range
    
    Me.ComboBox2.Clear
    
    Set ws = ActiveSheet
    Set tbl = ws.ListObjects("Tabelle1")
    
    With tbl
    
        'clear any pre-existing filters
        If .ShowAutoFilter Then
            With .AutoFilter
                If .FilterMode Then .ShowAllData
            End With
        End If
        
        With .Range
            .AutoFilter field:=1, Criteria1:=Me.ComboBox1.Value
            .AutoFilter field:=2, Criteria1:=">=" & Date
            .Sort Key1:=.Range("D5"), Order1:=xlAscending, Header:=xlYes
        End With
        
        On Error Resume Next
        Set rng = .DataBodyRange.SpecialCells(xlCellTypeVisible)
        On Error GoTo 0
        
        If rng Is Nothing Then Exit Sub
        
    End With
    
    Set resultsDictionary = CreateObject("Scripting.Dictionary")
    
    For Each rw In rng.Rows
        resultsDictionary(rw.Cells(2).Value) = "" 'second column/Gremientermin
    Next rw
    
    Me.ComboBox2.List = resultsDictionary.keys()
    
End Sub