如何对按帐户分组的前10名列表的动态Excel数组求和

3pvhb19x 于 2023-05-19 发布在其他

关注(0)|答案(1)|浏览(106)

我试图使一个动态数组具有选择性的顶部（无论... 5，10，12等）报告。使用Index/Sort/Unique/Sequence，我能够接近，但无法弄清楚如何对结果求和，以便将帐户的多次出现分组为单个数量总数。
我有一个表，EXAMPLE 1，有六列（DEALER，ORDER NO，ACCOUNT NAME，YEAR，MONTH，QTY）。我试图让我的动态数组，基于四个条件字段（DEALER -单元格I1，YEAR -单元格I2，MONTH -单元格I3，以及结果的行数-单元格I4），以降序显示按数量排序的结果，并按帐户总计数量。使用公式（我想我有点卡住了）

=INDEX(SORT(UNIQUE(FILTER(EXAMPLE1,(EXAMPLE1[DEALER]=$I$1)*(EXAMPLE1[YEAR]=$I$2)*(EXAMPLE1[MONTH]=$I$3),EXAMPLE1)),6,-1),SEQUENCE($I$4),{3,6})

我可以按出现次数获取数量，并按数量对要显示的行数进行排序，但如果某些帐户在EXAMPLE 1表中出现两次或更多次，则它们会重复。所以我得到

Bob's Boats 74
Marlin Sails Inc    71
Bob's Boats 42
Mike's Lemonade Stand   40
Labyrinth Walkways LLC  32
Direct Mailings LLC 16
Marlin Sails Inc    14

而不是

Bob's Boats 116
Marlin Sails Inc    85
Mike's Lemonade Stand   40
Labyrinth Walkways LLC  32
Direct Mailings LLC 16

我用了其他的公式，

=SORT(UNIQUE(FILTER(EXAMPLE1[ACCOUNT NAME],(EXAMPLE1[DEALER]=I1)*(EXAMPLE1[YEAR]=I2)*(EXAMPLE1[MONTH]=I3))))

对于帐户单元格，以及

=SUMIFS(EXAMPLE1[QTY],EXAMPLE1[DEALER],I1,EXAMPLE1[YEAR],I2,EXAMPLE1[MONTH],I3,EXAMPLE1[ACCOUNT NAME],K16#)

对于数量单元格，它按数量合计对帐户进行分组，但无法使该数组按数量排序或根据所需的行数提供结果。

Bob's Boats 116
Direct Mailings LLC 16
Labyrinth Walkways LLC  32
Marlin Sails Inc    85
Mike's Lemonade Stand   40

excel

来源：https://stackoverflow.com/questions/76255514/how-can-i-sum-a-dynamic-excel-array-for-top-10-list-grouped-by-account

1条答案

按热度按时间

v1l68za41#

不妨试试：

=TAKE(
    SORT(
        UNIQUE(
            HSTACK(
                EXAMPLE1[ACCOUNT NAME],
                SUMIFS(
                    EXAMPLE1[QTY],
                    EXAMPLE1[DEALER], I1,
                    EXAMPLE1[YEAR], I2,
                    EXAMPLE1[MONTH], I3,
                    EXAMPLE1[ACCOUNT NAME], EXAMPLE1[ACCOUNT NAME]
                )
            )
        ),2,-1
    ),I4
)

赞(0）回复(0）举报 2023-05-19

我来回答

如何对按帐户分组的前10名列表的动态Excel数组求和

1条答案

相关问题

热门标签

最新问答