APEX_JSON.GET_VARCHAR2返回varchar2 * 成员值 *。你发布的json有一个数组对象，该数组对象的 * meta * 路径有多个成员值。在这种情况下，循环遍历数组，并对每个数组成员值使用APEX_JSON.GET_VARCHAR2。

SET SERVEROUTPUT ON
DECLARE
  l_json_text VARCHAR2(32767);
  l_json_values    apex_json.t_values;
BEGIN
  l_json_text := '{
   "data":[
      [
         "2021-01-01",
         22,
         22,
         204,
         0.09090909090909091,
         22.545454545454547,
         1.0,
         6
      ],
      [
         "2021-01-10",
         21,
         21,
         173,
         0.2857142857142857,
         18.714285714285715,
         1.0,
         8
      ]
   ],
   "meta":{
      "columns":[
         "timestamp__to_date",
         "visitors",
         "sessions",
         "page_views",
         "goal_conversion_rate",
         "events_per_session",
         "returning_visitors_rate",
         "goal_conversions"
      ],
      "count":89
   }
}
';  

  apex_json.parse(
    p_values => l_json_values,
    p_source => l_json_text
  );

  DBMS_OUTPUT.put_line('----------------------------------------'); 
    IF apex_json.does_exist(p_path => 'meta.columns',p_values => l_json_values) THEN 
      dbms_output.put_line('meta.columns array elements: '||nvl(apex_json.get_count(p_path => 'meta.columns', p_values => l_json_values),0));
      FOR r IN 1 .. nvl(apex_json.get_count(p_path => 'meta.columns', p_values => l_json_values),0) loop
        dbms_output.put_line(apex_json.get_varchar2(p_path => 'meta.columns[%d]', p0 => r, p_values => l_json_values));
      END LOOP;
    END IF; 
  DBMS_OUTPUT.put_line('----------------------------------------'); 
END;
/

PL/SQL procedure successfully completed.

----------------------------------------
meta.columns array elements: 8
timestamp__to_date
visitors
sessions
page_views
goal_conversion_rate
events_per_session
returning_visitors_rate
goal_conversions
----------------------------------------