使用任何awk，而不是一次阅读所有输入到内存中：

awk '
    inBlock {
        if ( /^-+end-+$/ ) {
            if ( gsub(/\n/,"&",rec) <= 4 ) {
                printf "%s", rec
            }
            inBlock = rec = ""
        }
        else {
            rec = rec $0 ORS
        }
    }
    !inBlock {
        print
    }
    /^-+start-+$/ {
        inBlock = 1
    }
' file

------start---------
first line
second line
third line
fourth line
------end-----------
xyx
pqr
------start---------
------end-----------

使用GNU sed

$ sed -Ezi.bak 's/(-+start-+\n)(([^-\n]*\n){5,})(-+end-+\n)/\1\4/g' input_file
------start---------
first line
second line
third line
fourth line
------end-----------
xyx
pqr
------start---------
------end-----------

你可以用类似的方式使用perl代替sed：

perl -0pe 's/------start---------\n\K(?:(?:(?!------(?:end|start)---------).)+?\n){5,}(?=------end-----------)//g' myfile

这里perl -0pe是sed -z的替代品，但它支持PCRE正则表达式，包括lookaheads和捕获重置\K。
Regex本身意味着：

• ------start---------\n-以换行符开始标记，
• \K忽略先前匹配的序列，停留在相同的光标位置。替代它的可能是更广为人知的(?<=------start---------\n)，但\K具有更好的性能。
• (?:(?:(?!------(?:end|start)---------).)+?\n){5,}-至少5行不包含开始或结束标签，
• (?=------end-----------) lookahead检查匹配的序列后面是否有结束标记。

正则表达式here的演示。

awk \
    -v s1='------start---------' \
    -v s2='------end-----------' \
'
    # accumulate lines between markers
    between { data = data RS $0 }

    # found start marker
    $0==s1 {
        # reset state
        between = NR
        data = $0
    }

    # print anything outside markers
    !between;

    # found end marker
    $0==s2 {
        # print data if fewer than 6 lines total
        #     (including the two marker lines)
        # else just print the markers 
        print (NR < between+6) ? data : s1 RS s2

        # reset state
        between = 0
        data = ""
    }
' filename