如何将Admob和Firebase crashlytics添加到Android Studio bumble bee Build.gradle文件

pw9qyyiw 于 2023-06-04 发布在 Android

关注(0)|答案(4)|浏览(195)

如何将Admob和Firebase crashlytics添加到Android Studio Bumble Bee
build.gradle：是这样的

buildscript {
    repositories {
        google()
        mavenCentral()
        maven { url 'https://jitpack.io' }
    }
    dependencies {
        classpath "com.android.tools.build:gradle:7.0.4"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:1.6.10"
        // Add the following line:
        classpath 'com.google.gms:google-services:4.3.10'  // Google Services plugin
        // Add the Crashlytics Gradle plugin
        classpath 'com.google.firebase:firebase-crashlytics-gradle:2.8.1'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

然而现在的变化看起来像这样

plugins {
    id 'com.android.application' version '7.1.0' apply false
    id 'com.android.library' version '7.1.0' apply false
    id 'org.jetbrains.kotlin.android' version '1.6.10' apply false

    

}

task clean(type: Delete) {
    delete rootProject.buildDir
}

我试着加上这些线

// Add the following line:
        id 'com.google.gms:google-services' version '4.3.10' apply false
        // Google Services plugin
        // Add the Crashlytics Gradle plugin
        id 'com.google.firebase:firebase-crashlytics-gradle' version '2.8.1' apply false

但它的错误是

Caused by: org.gradle.plugin.internal.InvalidPluginIdException: plugin id 'com.google.gms:google-services' is invalid: Plugin id contains invalid char ':' (only ASCII alphanumeric characters, '.', '_' and '-' characters are valid)
    at org.gradle.plugin.use.internal.DefaultPluginId.validate(DefaultPluginId.java:65)
    at org.gradle.plugin.use.internal.DefaultPluginId.of(DefaultPluginId.java:48)
    at org.gradle.plugin.use.internal.PluginRequestCollector$PluginDependencySpecImpl.<init>(PluginRequestCollector.java:139)
    at org.gradle.plugin.use.internal.PluginRequestCollector$PluginDependencySpecImpl.<init>(PluginRequestCollector.java:129)
    at org.gradle.plugin.use.internal.PluginRequestCollector$PluginDependenciesSpecImpl.id(PluginRequestCollector.java:116)

android

来源：https://stackoverflow.com/questions/71060055/how-can-we-add-admob-and-firebase-crashlytics-to-android-studio-bumble-bee-build

4条答案

按热度按时间

polhcujo1#

像这样添加com.google.gms.google-services和com.google.firebase.crashlytics：

plugins {
    id 'com.android.application' version '7.1.0' apply false
    id 'com.android.library' version '7.1.0' apply false
    id 'org.jetbrains.kotlin.android' version '1.6.10' apply false

    
    id 'com.google.gms.google-services' version '4.3.10' apply false  // Google Services plugin
    // Crashlytics Gradle plugin
    id 'com.google.firebase.crashlytics' version '2.8.1' apply false
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

赞(0）回复(0）举报 2023-06-04

kq0g1dla2#

在plugins上方添加buildscript

buildscript {
  dependencies {
    // Add our classpath 
     classpath 'com.google.gms:google-services:4.3.10'
     classpath 'com.google.firebase:firebase-crashlytics-gradle:2.8.1' 
 }
}
 plugins {
      id 'com.android.application' version '7.1.0' apply false
      id 'com.android.library' version '7.1.0' apply false
}

task clean(type: Delete) {
   delete rootProject.buildDir
}

赞(0）回复(0）举报 2023-06-04

v1uwarro3#

在<project>/build.gradle中：

buildscript {
    repositories {
        google()
    }

    dependencies {
        classpath 'com.google.gms:google-services:4.3.13'
    }
}

// Top-level build file where you can add configuration options common to all sub-projects/modules`.

<project>/<app-module>/build.gradle：

plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
    id 'com.google.gms.google-services'//this one
}

在dependencies中：

implementation platform('com.google.firebase:firebase-bom:30.2.0')
implementation 'com.google.firebase:firebase-analytics-ktx'

赞(0）回复(0）举报 2023-06-04

pdtvr36n4#

对于KotlinDSL

id("com.google.firebase.crashlytics") version "2.9.5" apply false

赞(0）回复(0）举报 2023-06-04

我来回答

如何将Admob和Firebase crashlytics添加到Android Studio bumble bee Build.gradle文件

4条答案

相关问题

热门标签

最新问答