问题中的代码似乎有一个缺陷：Mycroft的魔法常数还没有扩展到64位。关于效率：各种x86-64调用约定主要是基于寄存器的，因此不必为简单函数维护堆栈帧。发布的代码中的主循环似乎有点过于复杂;注意，大多数x86指令设置可用于分支的标志。达到下一个QWORD边界的逐字节处理可能会受益于完全展开。
下面是为Windows编写的x86-64代码，其中包含了这些建议。将其调整到Linux使用的System V ABI只需要循环交换寄存器。请注意，在具有BMI指令集扩展的CPU上，通过将not rcx与以下and rcx, r9合并为andn rcx, rcx, r9，可以将64位处理循环减少一条指令。

PUBLIC  strglen

_TEXT   SEGMENT

        ALIGN 16

;; Alan Mycroft's null-byte detection algorithm (newsgroup comp.lang.c, 1987/04/08,
;; https://groups.google.com/forum/#!original/comp.lang.c/2HtQXvg7iKc/xOJeipH6KLMJ):
;; null_byte(x) = ((x - 0x01010101) & (~x & 0x80808080))
 
mycroft_magic1 EQU 0101010101010101h
mycroft_magic2 EQU 8080808080808080h 

;; size_t strglen (const char *src);

;; Windows x86-64 calling convention:
;; function arguments: rcx, rdx, r8, r9
;; function return value: rax
;; scratch registers: rax, rcx, rdx, r8, r9, r10, r11

strglen PROC
        mov    rax, rcx             ; src pointer
        mov    r8, rcx              ; src pointer
        mov    r9, mycroft_magic2   ; 0x8080808080808080
        mov    r10, -mycroft_magic1 ; 0x0101010101010101

        and    rcx, 7               ; is src qword aligned ?
        jz     count_bytes          ; yes, process qword wise

BYTE_OFS = 7
REPT 6  
        cmp    byte ptr [rax], 0    ; *src == 0 ?
        je     done                 ; yes
        inc    rax                  ; src++
        cmp    rcx, BYTE_OFS        ; src now qword aligned?
        je     count_bytes          ; yes, process qword-wise
BYTE_OFS = BYTE_OFS-1
ENDM
        cmp    byte ptr [rax], 0    ; *src == 0 ?
        je     done                 ; yes
        inc    rax                  ; src++

        ALIGN 16

count_bytes:
        mov    rcx, [rax]           ; load aligned qword
        add    rax, 8               ; src += 8
        lea    rdx, [rcx + r10]     ; qword - 0x0101010101010101
        not    rcx                  ; ~qword
        and    rcx, r9              ; ~qword & 0x8080808080808080
        and    rcx, rdx             ; (qword - 0x0101010101010101) & (~qword & 0x8080808080808080)
        jz     count_bytes          ; if zero, no null byte found -- continue

has_zero_byte:
        bsf     rcx, rcx            ; find first set bit (null byte)
        shr     rcx, 3              ; convert bit position to byte position
        lea     rax, [rax + rcx - 8]; reverse pre-increment to compute byte count
done:
        sub     rax, r8             ; src - original src = length
        ret

strglen ENDP

        ALIGN 16

_TEXT   ENDS

        END

我使用下面的ISO-C99测试脚手架来检查上面的strglen实现的正确性。我使用Microsoft Macro Assembler和Intel C/C++编译器构建，如下所示：ml64 -c strglen.asm、icl /Qstd=c99 /Ox /W4 strlen.c strglen.obj。我还用dumpbin /disasm strglen.obj检查了生成的机器代码，主要是为了确保对齐指令按预期工作，以及通过REPT宏展开的循环正确工作，因为我在过去的20年里没有使用过它。

#include <stdio.h>
#include <stdlib.h>
#include <string.h>

extern size_t strglen (const char* str);

int main (void)
{
    const char a[] = "0123456789 the quick brown fox jumps over the lazy dog";
    char* src =  malloc (sizeof(a));
    size_t ref, res;

    printf ("src=%p\n", a);

    for (int srcofs = 0; srcofs < 8; srcofs++) {
        for (size_t len = 0; len < sizeof(a); len++) {
            memcpy (src, a, sizeof(a));
            src [len] = 0;
            ref = strlen (src + srcofs);
            res = strglen (src + srcofs);
            if (res != ref) {
                printf ("error @ srcofs=%d  len=%zu  ref=%zu  res=%zu\n", 
                        srcofs, len, ref, res);
                return EXIT_FAILURE;
            }
        }
    }
    printf ("Test passed\n");
    return EXIT_SUCCESS;
}