从问题和OP的评论中得出的假设/理解：

• 所有字段（包括标题字段）都用双引号括起来
• 字段之间用逗号分隔，逗号两侧可能还有空格
• 字段可以包含逗号
• 字段不包含嵌入的换行符

根据（上述）假设制作一些样本数据：

$ cat headers.csv
eid
24503-1.0
4526-1.0

$ cat data_file.csv
"eid","24500-0.0", "24503-0.0", "24503-1.0","4526-0.0", "4526-1.0"
"AB1","1","a","0,111","1.2",""
"CD2","2","b","9","","-123,be"

一个GNU awk（用于FPAT支持）：

awk '
BEGIN   { FPAT = "([^,]+)|(\"[^\"]+\")" }                   # define field patterns

        # remove following block if we do NOT have to worry about white space before/after the comma delimiter

        { for ( i=1;i<=NF;i++ )                             # for all fields ...
              gsub(/^[[:space:]]+|[[:space:]]+$/,"",$i)     # strip leading/trailing white space
        }

FNR==NR { hdr["\"" $1 "\""]                                 # 1st file: populate array of headers
          next
        }

FNR==1  { for ( i=1;i<=NF;i++ )                             # 2nd file: process header fields
              if ( $i in hdr )                              # if in our hdr[] array then 
                 cols[++colcnt] = i                         # populate array of columns making note of their order
        }
        { for ( i=1;i<=colcnt;i++ )                         # 2nd file: for each data line loop through list of desired columns and print to stdout
              printf "%s%s", $(cols[i]), (i<colcnt ? "," : ORS)
        }
' headers.csv data_file.csv

这产生：

"eid","24503-1.0","4526-1.0"
"AB1","0,111",""
"CD2","9","-123,be"

您在评论中指出您正在使用英国生物库数据集。Biobank为Windows和Linux提供了一个转换实用程序ukbconv：https://biobank.ctsu.ox.ac.uk/crystal/download.cgi
根据this pdf和官方文档，给定文本文件中的字段编号列表，直接从原始文件中提取相关列为适合R的格式的命令为：

ukbconv dataset.enc_ukb r -ifield_list.txt

文档区分了“字段”和“列”：
例如，假设我们只想从数据集中提取字段31、20204和40000，并将其转换为csv格式。我们创建一个名为field_list.txt的文本文件，其内容如下：

31
20204
40000

并将其放入与ukbconv相同的文件夹中。然后我们运行命令：

ukbconv ukb23456.enc_ukb csv -ifield_list.txt

结果输出将仅包含eid列以及Data-Fields 31、20204和40000的所有示例和数组组合的列（假设这些Data-Fields存在于.enc_ukb文件中）。
为了帮助准备提供所需字段列表的文件，ukbconv每次运行时都会输出名为field.ukb的文件，该文件列出了与数据集相关的所有可用字段。这可以被编辑以标识要被包括在子集中或从子集中排除的特定字段。
它还讨论了“示例和数组索引”，并指出在csv的情况下：
列标题的格式为F-I.A，其中F是数据字段编号，I是示例索引，A是数组索引
这看起来像你的问题的头格式，所以它可能是，通过使用ukbconv，你最终会得到更多的数据比你要求的（即。额外的列）。这对你来说可能是个问题，也可能不是。