看起来像是试图创建一个对象，作为Form1上的文本框的中介。如果是这种情况，你应该在创建Purchase对象时传递一个对Form1的引用：

Public Class Purchase

    Private _form As Form1

    Public Sub New(form As Form1)
        _form = form
    End Sub

    Public Property description() As String
        Get
            Return _form.txtitem.Text
        End Get
        Set(value As String)
            _form.txtitem.Text = value
        End Set
    End Property
    Public Property quantity() As Integer
        Get
            Return Ctype(_form.txtquantity.Text, Integer)
        End Get
        Set(value As Integer)
            _form.txtquantity.Text = value.ToString
        End Set
    End Property
    Public Property price() As Double
        Get
            Return CType(_form.txtprice.Text, Double)
        End Get
        Set(value As Double)
            _form.txtprice.Text = value.ToString
        End Set
    End Property

End Class

更好的方法是在Purchase类上添加事件，并在事件引发时更新Form：

Public Class Purchase

    Private _description As String
    Private _quantity As Integer
    Private _price As Double

    Public Event HasBeenUpdated(sender As Object, e As EventArgs)

    Public Property description() As String
        Get
            Return _description
        End Get
        Set(value As String)
            If _description <> value Then
                _description = value
                RaiseEvent HasBeenUpdated(Me, EventArgs.Empty)
            End If
        End Set
    End Property
    Public Property quantity() As Integer
        Get
            Return _quantity
        End Get
        Set(value As Integer)
            If _quantity <> value Then
                _quantity = value
                RaiseEvent HasBeenUpdated(Me, EventArgs.Empty)
            End If
        End Set
    End Property
    Public Property price() As Double
        Get
            Return _price
        End Get
        Set(value As Double)
            If _price <> value Then
                _price = value
                RaiseEvent HasBeenUpdated(Me, EventArgs.Empty)
            End If
        End Set
    End Property

End Class

在Form1中，您可以创建Purchase的示例并处理其HasBeenUpdated事件：

Private WithEvents _purchase As New Purchase

Private Sub _purchase_HasBeenUpdated(sender As Object, e As EventArgs) Handles _purchase.HasBeenUpdated
    txtDescription.Text = _purchase.description
    txtQuantity.Text = _purchase.quantity.ToString
    txtPrice.Text = _purchase.price.ToString
End Sub

当数据输入完成时，您还需要更新Purchase对象，可能需要使用保存按钮：

Private Sub SavePurchaseData()
    With _purchase
        .description = txtDescription.Text
        .quantity = CType(txtQuantity.Text, Integer)
        .price = CType(txtPrice.Text, Double)
    End With
End Sub