你需要使用一个循环：

Sub Hyperlink()
    Dim ws As Worksheet, c As Range, rngLinks As Range, url, txt
    
    Set ws = ActiveSheet
    Set rngLinks = ws.Range("G2:G1054")
    rngLinks.Hyperlinks.Delete

    For Each c In rngLinks
        url = c.EntireRow.Columns("S").Value
        txt = c.EntireRow.Columns("V").Value
        If Not IsError(url) And Not IsError(txt) Then
            If Len(url) > 0 And Len(txt) > 0 Then
                ws.Hyperlinks.Add Anchor:=c, _
                   Address:=url, TextToDisplay:=txt
            End If  'not empty
        End If      'not error
    Next c

End Sub

看起来您使用的是宏记录器输出的更改版本。这里的问题是ActiveSheet.Hyperlinks.Add一次只处理一个单元格，所以不能给予它一个包含多个单元格的范围。
相反，您需要使用循环。例如：

Sub Hyperlink()

    'Define your workbook variable
    Dim wb As Workbook
    Set wb = ThisWorkbook 'Or use Workbooks("<YourWorkbookName>")
    
    'Define your worksheet variable
    Dim ws As Worksheet
    Set ws = wb.Sheets("Sheet1") 'Replace with your sheet name
    
    'Define your ranges
    Dim DestinationRange As Range
    Set DestinationRange = ws.Range("G2:G1054")
       
    Dim AddressRange As Range
    Set AddressRange = ws.Range("S2:S1054")
    
    Dim TextToDiplayRange As Range
    Set TextToDiplayRange = ws.Range("V2:V1054")
        
    'Apply hyperlinks to one cell at a time.
    Dim i As Long
    For i = 1 To DestinationRange.Cells.Count
           
        ws.Hyperlinks.Add Anchor:=DestinationRange.Cells(i, 1), _
            Address:=AddressRange.Cells(i, 1).Value2, _
            TextToDisplay:=TextToDiplayRange.Cells(i, 1).Value2
            
    Next

End Sub

请注意，如果您无论如何都要覆盖以前的超链接，则不需要删除它们。