考虑到您希望configDataJSON被逐字显示，您真的不需要进一步操作它。
在下面的示例中，我使用importstr按原样加载configdata.json，然后构建两个数据字段：一个来自加载的JSON的逐字记录，然后另一个通过jsonnet更改了它的一个字段，只是为了向你展示应该如何完成可能的转换（在你的原始用例中 * 不需要 *）：

foo.jsonnet

local confData = importstr 'configdata.json';

local config(confData) = (
  local configMap = {
    apiVersion: 'v1',
    kind: 'ConfigMap',
    metadata: {
      name: 'myname',
      namespace: 'mynamespace',
      labels: { app: 'myname' },
    },
    // data fields need to be: { key: value }, both as strings
    data: {
      // verbatim JSON manifested as string
      'confData.json': confData,
      // original JSON parsed into jsonnet object, modified, then manifested as string
      'confData2.json': std.manifestJson(
        std.parseJson(confData) { foo: 'otherBar' }
      ),
    },
  };
  configMap
);

config(confData)

configdata.json

{
  "foo": "bar",
  "qqq": "qux"
}

输出

$ jsonnet foo.jsonnet | jq -r '.data["confData.json"]' 
{
  "foo": "bar",
  "qqq": "qux"
}

$ jsonnet foo.jsonnet | jq -r '.data["confData2.json"]'
{
    "foo": "otherBar",
    "qqq": "qux"
}

$ jsonnet foo.jsonnet | kubeconform -verbose
stdin - ConfigMap myname is valid