PrinterSettings.InstalledPrinters是枚举可用打印机名称的字符串集合。您可以用不同的方式筛选此集合，以便只选择要显示的打印机。
在这里，使用LINQ的Where()方法，集合被过滤，选择包含您要查找的名称的一部分的字符串：

dim myPrinters = PrinterSettings.InstalledPrinters.OfType(Of String).
                 Where(Function(p) p.Contains("1ABC")).ToList()

字符串
您可以添加**OrElse**条件来包含其他过滤器。例如：

.Where(Function(p) p.Contains("1ABC") OrElse p.StartsWith("Network1"))

型
在枚举打印机之前，应验证后台打印程序服务是否实际可用。您可以使用ServiceController类来检查**spooler**服务的Status属性，看看它是否是ServiceControllerStatus.Running，并对其进行操作。如果后台打印程序未运行，则如果您尝试以任何方式枚举可用打印机，则会出现异常。
▶将项目引用添加到System.ServiceProcess程序集。
当您尝试执行此枚举时，还可能会得到其他异常，这取决于不同的条件，因此最好捕捉这些异常并做出不同的选择。
举个例子：
作为一个建议，给你的控件起一个有意义的名字，以防这些是你正在使用的实际名字

Imports System.Drawing.Printing
Imports System.Linq
Imports System.ServiceProcess

Private Const RPC_ERROR As Integer = 1722

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

    Button1.Text = "Set Default Printer"
    Button1.Enabled = False

    Dim spoolerStatus = New ServiceController("spooler").Status

    If spoolerStatus = ServiceControllerStatus.Running Then
        Try
            Dim myPrinters = PrinterSettings.InstalledPrinters.OfType(Of String).
                Where(Function(p) p.Contains("1ABC")).ToList()
            If myPrinters.Count > 0 Then
                ComboBox1.DataSource = myPrinters
                Button1.Enabled = True
            Else
                ComboBox1.Items.Add("<Printer not installed>")
            End If
        Catch wEx As Win32Exception
            If wEx.NativeErrorCode = RPC_ERROR Then
                ' RPC Server unavailable
                ComboBox1.Items.Add($"<{wEx.Message}>")
            Else
                ' Log Message
                MessageBox.Show(wEx.Message)
                ComboBox1.Items.Add("<Error>")
            End If
        Catch ex As Exception
            ' Log Message
            MessageBox.Show(ex.Message)
            ComboBox1.Items.Add("<Error>")
        End Try
    Else
        ComboBox1.Items.Add("<Spooler Service not available>")
    End If
    ComboBox1.SelectedIndex = 0
End Sub

型
要更改默认打印机，我建议使用SetdefaultPrinter Win32函数或相应的WMI的Win32_Printer类SetDefaultPrinter方法。
▶当您单击Button设置新的默认打印机时，请使用GetItemText()方法获取ComboBox1.SelectedItem内容，不要依赖该控件的Text属性。

Imports System.Runtime.InteropServices

<DllImport("winspool.drv", CharSet:=CharSet.Auto, SetLastError:=True)>
Friend Shared Function SetDefaultPrinter(printerName As String) As Boolean
End Function

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Dim printeNname = ComboBox1.GetItemText(ComboBox1.SelectedItem)
    If SetDefaultPrinter(printeNname) Then
         MessageBox.Show($"Your default printer is now {printeNname}")
    Else
         MessageBox.Show("Couldn't change the default printer")
    End If
    Me.Close()
End Sub

型